F＃：使用C＃中的F＃索引属性

Question

I have written a class in F# implementing an interface in order to build a C#-friendly interface for my F#-assembly.

I have written some of the properties as indexed properties. However, when I try to use the type from C#, I only get the synthetic get_PropertyName methods in intellisense and the compiler likewise complains in case I want to use the indexed properties like I would do for C# ones.

Code for reference:

type IMyInterfaceType =   
    abstract MyProperty : MyType1 with get
    abstract MyIndexedProperty : MyType2 -> MyType3 with get
    abstract MyTwoDimensionalIndexedProperty : (MyType4 * MyType5) -> MyType6 with get

type MyInterfaceType =   

    new () = { }

    interface IMyInterfaceType with
        member this.MyProperty with get () = new MyType1 ()
        member this.MyIndexedProperty with get parameter = new MyType3 ()
        member this.MyTwoDimensionalIndexedProperty with get pair = new MyType6 ()

When trying to access this class from C#, I only get methods

get_MyIndexedProperty(MyType2 parameter)
get_MyTwoDimensionalIndexedProperty(Tuple<MyType4, MyType5>)

instead of the indexed properties I had hoped for.

Am I doing something wrong or is this a known issue?

cheers
--Mathias.

Answer 1

Response to the original question :

Indexer properties in C# have special name Item thus to create indexer accessible from C# you must name your indexer property "Item", eg:

type X () =
    member this.Item with get key = ....

Now it can be accessed both in F# using (x : X).[key] or in C# using x[key] .

Response to the updated question :

C# does not support indexed properties the way F# does. Instead using additional type is advised: https://msdn.microsoft.com/en-us/library/aa288464%28v=vs.71%29.aspx

So you can try to use something like this:

[<AbstractClass>]
type Indexer<'index, 'result> () =
    abstract Get : 'index -> 'result
    member this.Item with get key = this.Get key

type IMyInterfaceType =   
    abstract MyProperty : MyType1 with get
    // F# indexed propetties
    abstract MyIndexedProperty : MyType2 -> MyType3 with get
    // C# workaround
    abstract MyCSharpIndexedProperty : Indexer<MyType2, MyType3> with get

type MyInterfaceType () as this =
    let proxy =
      { new Indexer<MyType2, MyType3> () with
          member __.Get key = (this :> IMyInterfaceType).MyIndexedProperty key }
    interface IMyInterfaceType with
        member __.MyProperty with get () = new MyType1 ()
        member __.MyIndexedProperty with get key = new MyType3 ()
        member __.MyCSharpIndexedProperty with get () = proxy

And two dimensional property similarly by creating Indexer<'index1, 'index2, 'result> () = ...