尝试使用图形库Ocaml移动圆

Question

I am new to ocaml and trying to move a circle using Graphics library of Ocaml. This is what I did but it is not working. It should continue for infinite time because of "while true" but it is not working and I am not able to give an Input.

#load "graphics.cma";;
#load "unix.cma";;

Graphics.open_graph " 800x250";;
Graphics.remember_mode true;;
Graphics.set_color 100;;
Graphics.foreground;;

let player = [|40;80;10|];;

Graphics.fill_circle player.(0) player.(1) player.(2);;

let rec check button = 
    if button = 'w'
    then
    player.(0) <- player.(0) + 50;
    Graphics.fill_circle player.(0) player.(1) player.(2);

while true do
    let s = Graphics.wait_next_event [Graphics.Button_down; Graphics.Key_pressed]
    and bo=Graphics.key_pressed ()
    in if not bo then check s.Graphics.key;
    done;;

Answer 1

Here is the cause of problems:

 Graphics.fill_circle player.(0) player.(1) player.(2);
                                                 ^^^^^^^
                       here should be a double semicolon

Without a second semicolon, the while expression was considered as a part of check function, the proper indentation clarifies this:

let rec check button = 
  if button = 'w'
  then
    player.(0) <- player.(0) + 50;
  Graphics.fill_circle player.(0) player.(1) player.(2);

  while true do
    let s = Graphics.wait_next_event [Graphics.Button_down; Graphics.Key_pressed]
    and bo=Graphics.key_pressed ()
    in if not bo then check s.Graphics.key;
  done

So, you just defined a function check, and never called it, that's why nothing was happening.

Also, OCaml is a programming language, so it is better to try to write OCaml programs, not scripts. Put the following in a graph.ml file,

let player = [|40;80;10|]

let init () = 
  Graphics.open_graph " 800x250";
  Graphics.remember_mode true;
  Graphics.set_color 100;
  Graphics.fill_circle player.(0) player.(1) player.(2)

let rec check button = 
  if button = 'w'
  then
    player.(0) <- player.(0) + 50;
  Graphics.fill_circle player.(0) player.(1) player.(2)

let run () = 
  while true do
    let s = Graphics.wait_next_event [
        Graphics.Button_down;
        Graphics.Key_pressed
      ] in
    let bo = Graphics.key_pressed () in
    if not bo then check s.Graphics.key;
  done


let () =
  init ();
  run ()

Compile and run it with the following command

 ocamlbuild -pkg graphics graph.native --