用正则表达式在 Bash 或 Perl 中定义一个变量

Question

I have a file that has some lines like this:

{"v":0,"_id":"54ff561168a","time":"1421165205"}

I want to use bash that read each line and set the value of the time as Variable (t) and replace it with other timestamp using date -d @{$t}

Do you know how can I use regular expression for getting the value of time as variable?

Answer 1

That is JSON . You can parse JSON in perl like so:

#!/usr/bin/perl 
use strict;
use warnings;
use JSON;
use Data::Dumper; 

my $text = '{"v":0,"_id":"54ff561168a","time":"1421165205"}';

my $data = decode_json ( $text );
print Dumper $data;

print $data -> {"time"},"\n";

$data -> {"time"} = time();

$text = encode_json($data);

print "Result:\n";
print $text;

You don't need regular expressions - and indeed, you should actively avoid them, because JSON allows you to format your data with eg line feeds/indentation - and is semantically identical.

Eg you could output your example above as:

{
   "_id" : "54ff561168a",
   "time" : 1433859139,
   "v" : 0
}

By using:

$text = to_json($data, {pretty => 1});

It means the same thing, but different regular expressions apply thanks to changing whitespace etc.

If you wish to manipulate/reformat your timestamp, I'll refer you to the excellent Time::Piece module:

use Time::Piece;
my $t = localtime ( $data -> {"time"} );
print $t;

Will give:

Tue Jan 13 16:06:45 2015

If you want a specific format:

print $t->strftime("%Y/%m/%d %H:%M:%S"),"\n";

Giving:

2015/01/13 16:06:45