在另一张纸上打印，为什么不工作？

Question

So I have this button code to clock in and clock out and it works fine, but my problem is that the button is on the first sheet and I need it to stamp the time on a different sheet called Timesheet. Here is my code. I thought if I replaced the word Location that was in every parenthesis with the word Timesheet and it will just not stamp the time in the Timesheet.

Sub StampNext()
    Dim r As Range
    On Error Resume Next
    Set r = Range("Timesheet")
    On Error GoTo 0
    If r Is Nothing Then Range("A1").Name = "Timesheet"
    With Range("Timesheet")
        .Value = Time
        .NumberFormat = "hh:mm"
        If .Row = 1 Then
            .Offset(2, 0).Name = "Timesheet"
        Else
            .Offset(-2, 1).Name = "Timesheet"
        End If
    End With
End Sub

I also have the Timesheet protected because my boss doesn't want the employee to tamper with the sheet. I don't know if that would be a hindering problem to the code or if that just doesn't matter.

Answer 1

You need to declare the worksheet object and then you can write to it.

Dim ws1 As Excel.Worksheet
Set ws1 = ActiveWorkbook.Sheets("Timesheet")

ws1.Range("A1").Value = Time

I'm not sure about the protected sheet, but my guess is you will have to unprotect it temporarily.

Answer 2

Sub StampNext()

    'Declare a variable as a worksheet and a variable for the named range
    Dim wsT As Worksheet
    Dim wsA as Worksheet
    Dim rngT As Range

    'Set that variable to the worksheet named "Timesheet"
    Set wsT = ThisWorkbook.Worksheets("Timesheet")
    Set wsA = ActiveSheet

    'Unprotect the sheet using the password.
    '(Note: you should protect the VBA project from viewing to
    ' prevent others from viewing the password.)
    wsT.Unprotect ("sheetPassword")
    wsT.Activate

    'Set Range variable
    On Error Resume Next
    Set rngT = wsT.Range("Timesheet")
    On Error GoTo 0

    If rngT Is Nothing Then
        wsT.Range("A1").Name = "Timesheet"
        Set rngT = wsT.Range("Timesheet")
    End If


   'Add value and update the named range "Timesheet"
   With rngT
        .Value = Time
        .NumberFormat = "hh:mm"

        If .Row = 1 Then
            .Offset(2, 0).Name = "Timesheet"
        Else
            .Offset(-2, 1).Name = "Timesheet"
        End If
    End With

    'Reprotect sheet with password
    wsT.Protect ("sheetPassword")
    wsA.activate
End Sub