尽管值相同，为什么这张表上的日期不突出显示

Question

I've got a macro code to highlight cells in a sheet where the value comes from another sheet upon a button click on a separate sheet but it is returning value can't be found/none found when the value on both sheets is actually the same.

The value of the cell is a date value.

the 1st is the intended sheet and the 2nd one is the code

intended sheet to highlight cells

Sub HighlightSpecificValue()
    Dim fnd As String, FirstFound As String
    Dim FoundCell As Range, rng As Range
    Dim myRange As Range, LastCell As Range
    fnd = Range("H9").Value
    Sheets("PO copy").Select
    Set myRange = ActiveSheet.UsedRange
    Set LastCell = myRange.Cells(myRange.Cells.Count)
    Set FoundCell = myRange.Find(what:=fnd, after:=LastCell)
    If Not FoundCell Is Nothing Then
        FirstFound = FoundCell.Address
    Else
        GoTo NothingFound
    End If  
    Set rng = FoundCell
    Do Until FoundCell Is Nothing
        Set FoundCell = myRange.FindNext(after:=FoundCell)
        Set rng = Union(rng, FoundCell)
        If FoundCell.Address = FirstFound Then Exit Do
    Loop
    rng.Interior.Color = RGB(255, 255, 0)
    Exit Sub
NothingFound:
    MsgBox "No cells containing: " & fnd & " were found in this worksheet"
End Sub

Answer 1

A couple of things need to be fixed:

• You shouldn't try to compare a String to a cell containing a date - so it will be best to define fnd as a Variant
• You are currently not specifying whether to look at values or formulas when doing the Find , or whether to look at part or the whole of the value - you should explicitly define those in order to avoid confusion due to Excel using whatever the user last used

I believe the following, slightly modified, code should work:

Sub HighlightSpecificValue()
    Dim fnd As Variant, FirstFound As String
    Dim FoundCell As Range, rng As Range
    Dim myRange As Range, LastCell As Range
    fnd = Range("H9").Value
    Sheets("PO copy").Select
    Set myRange = ActiveSheet.UsedRange
    Set LastCell = myRange.Cells(myRange.Cells.Count)
    Set FoundCell = myRange.Find(what:=fnd, _
                                 after:=LastCell, _
                                 LookIn:=xlValues, _
                                 LookAt:=xlWhole)
    If Not FoundCell Is Nothing Then
        FirstFound = FoundCell.Address
    Else
        GoTo NothingFound
    End If  
    Set rng = FoundCell
    Do Until FoundCell Is Nothing
        Set FoundCell = myRange.FindNext(after:=FoundCell)
        Set rng = Union(rng, FoundCell)
        If FoundCell.Address = FirstFound Then Exit Do
    Loop
    rng.Interior.Color = RGB(255, 255, 0)
    Exit Sub
NothingFound:
    MsgBox "No cells containing: " & fnd & " were found in this worksheet"
End Sub