如何将文本从一个文本框中显示到另一个文本框中

Question

The code is used for using VB.NET to run CMD. What I want to do, is when I type in "ipconfig" and click ExecuteButton, a lot of text will appear, and one of those words will be "DNS". When the word "DNS" has appeared in OutputTextBox, I want StatusTextBox to display the text "It Works".

Here is the code:

Public Class Form1

Private WithEvents MyProcess As Process
Private Delegate Sub AppendOutputTextDelegate(ByVal text As String)



Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
    Me.AcceptButton = ExecuteButton
    MyProcess = New Process
    With MyProcess.StartInfo
        .FileName = "CMD.EXE"
        .UseShellExecute = False
        .CreateNoWindow = True
        .RedirectStandardInput = True
        .RedirectStandardOutput = True
        .RedirectStandardError = True
    End With
    MyProcess.Start()

    MyProcess.BeginErrorReadLine()
    MyProcess.BeginOutputReadLine()
    AppendOutputText("Process Started at: " & MyProcess.StartTime.ToString)

    If OutputTextBox.Text = "DNS" Then
        StatusTextBox.Text = "It Works"
    End If

End Sub

Private Sub Form1_FormClosing(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing
    MyProcess.StandardInput.WriteLine("EXIT")
    MyProcess.StandardInput.Flush()
    MyProcess.Close()
End Sub

Private Sub MyProcess_ErrorDataReceived(ByVal sender As Object, ByVal e As System.Diagnostics.DataReceivedEventArgs) Handles MyProcess.ErrorDataReceived
    AppendOutputText(vbCrLf & "Error: " & e.Data)
End Sub

Private Sub MyProcess_OutputDataReceived(ByVal sender As Object, ByVal e As System.Diagnostics.DataReceivedEventArgs) Handles MyProcess.OutputDataReceived
    AppendOutputText(vbCrLf & e.Data)
End Sub

Private Sub ExecuteButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ExecuteButton.Click
    MyProcess.StandardInput.WriteLine(InputTextBox.Text)
    MyProcess.StandardInput.Flush()
    InputTextBox.Text = ""
End Sub

Private Sub AppendOutputText(ByVal text As String)
    If OutputTextBox.InvokeRequired Then
        Dim myDelegate As New AppendOutputTextDelegate(AddressOf AppendOutputText)
        Me.Invoke(myDelegate, text)
    Else
        OutputTextBox.AppendText(text)
    End If
End Sub
End Class

Here is an example of what it looks like:

To point out my problem, here is what I try to do:

    If OutputTextBox.Text = "DNS" Then
    StatusTextBox.Text = "It Works"
End If

When I do type in "ipconfig" the text "DNS" will show up but nothing happens to StatusTextBox. What am I doing wrong?

Answer 1

Your Form Load event is never waiting, so it is checking your conditional statement immediately. Can you move the conditional statement to your OutputDataReceived Sub?

Also, your OutputTextBox is appending data, so I can't see it ever equaling "DNS". Are you looking to see if it .Contains("DNS")?

And if you move the conditional to OutputDataReceived, and you're appending to the OutputTextBox, do you just want to see if e.Data.Contains("DNS")?

-- edit --

Private Delegate Sub ChangeStatusTextDelegate(ByVal text As String)

Private Sub MyProcess_OutputDataReceived(ByVal sender As Object, ByVal e As System.Diagnostics.DataReceivedEventArgs) Handles MyProcess.OutputDataReceived
    AppendOutputText(vbCrLf & e.Data)

    If e.Data.Contains("DNS") Then
        ChangeStatusText("It works")
    End If
End Sub

Private Sub ChangeStatusText(ByVal text As String)
    If txtStatus.InvokeRequired Then
        Dim myDelegate As New ChangeStatusTextDelegate(AddressOf ChangeStatusText)
        Me.Invoke(myDelegate, text)
    Else
        Me.StatusTextBox.Text = text
    End If
End Sub