在网页上的登录表单中输入用户名和密码

Question

Using Excel VBA, I'm trying to login to a website.

This is my code:

Dim HTMLDoc As HTMLDocument
Dim oBrowser As InternetExplorer
Sub Website_Login()

Dim oHTML_Element As IHTMLElement
Dim sURL As String

sURL = "https://www.domain.com/login.html"

Set oBrowser = New InternetExplorer
'oBrowser.Silent = True
'oBrowser.timeout = 60
oBrowser.navigate sURL
oBrowser.Visible = True

Do
Loop Until oBrowser.ReadyState = READYSTATE_COMPLETE

Set HTMLDoc = oBrowser.Document

With HTMLDoc
  HTMLDoc.getElementById("username").Value = "user"
  HTMLDoc.getElementById("password").Value = "password"
End With

For Each oHTML_Element In HTMLDoc.getElementsByTagName("input")
  oHTML_Element.Click
  Exit For
Next

oBrowser.Quit

End Sub

The Javascript instructions in this code are working. If I go to the page and enter them, they work. But when I run the code, IE opens but it doesn't enter the user/pass and click the button.

Any help, please?

Answer 1

I just tested this code and it worked.

The only difference is that I used Late Binding (too lazy to set all references) and I added While .Busy to the Loop to wait for the URL to load. I also changed input to button in the button click loop.

Dim HTMLDoc As Object 'HTMLDocument
Dim oBrowser As Object 'InternetExplorer

Sub Website_Login()

Dim oHTML_Element As Object 'IHTMLElement
Dim sURL As String

sURL = "https://www.mypage.com/login.html"
Set oBrowser = CreateObject("InternetExplorer.Application") 'New InternetExplorer
'oBrowser.Silent = True
'oBrowser.timeout = 60
oBrowser.navigate sURL
oBrowser.Visible = True

With oBrowser
    Do While .Busy Or .ReadyState <> 4: Loop
End With


Set HTMLDoc = oBrowser.Document

With HTMLDoc
  HTMLDoc.getElementById("username").Value = "user"
  HTMLDoc.getElementById("password").Value = "password"
End With

For Each oHTML_Element In HTMLDoc.getElementsByTagName("button")
  If oHTML_Element.Name = "Submit" Then oHTML_Element.Click
  Exit For
Next

oBrowser.Quit

End Sub