DoWhile循环中vlookup公式中的Excel VBA引用命名为工作簿

Question

This seems like it should be simple, but I'm really stuck on it.

This is code to get values from multiple workbooks in a directory and compile them in one workbook. I am using vlookup because the value is not always in the exact same cell, but always has the same row header. The code opens each workbook in the directory and names it wb.

I want to reference wb in the Vlookup formula but am having trouble doing it. When I try the code below it gives me a "loop without do" error (but when I run the same code without the formula, just copying and pasting ranges, it is fine). I've also tried naming a range in wb and referencing that.

'Target File Extension
  myExtension = "*.xls"

'Target Path with Ending Extention
 myFile = Dir(myPath & myExtension)

'Loop through each Excel file in folder
  Do While myFile <> ""

'Set variable equal to opened workbook
  Set wb = Workbooks.Open(fileName:=myPath & myFile)

'Put ID from filename into sheet
  If right(wb.Name, 5) = "h.xls" Then
    wb.Worksheets(1).Range("B16").Select
    ActiveCell.Value = Left(wb.Name, 9)

'Get value from wb using Vlookup
  MasterBook.Activate
    ActiveCell.Offset(1, 0).Select
    ActiveCell.FormulaR1C1 = "=VLOOKUP(""Sugar (g)"",wb!R18C1:R28C6,2,FALSE)"
'Close Workbook
  wb.Close SaveChanges:=True

'Get next file name
  myFile = Dir
Loop

'Message Box when done
  MsgBox "Task Complete!"

Answer 1

You cannot use the Range object directly when putting together a string to be used as a formula. Concatenate the Range.Address property into the string.

ActiveCell.FormulaR1C1 = "=VLOOKUP(""Sugar (g)"", " &  _
                      wb.Worksheets(1).Range("A18:F28").address(External:=true, ReferenceStyle:=xlR1C1) & _
                      ", 2, FALSE)"
'or,
ActiveCell.Formula = "=VLOOKUP(""Sugar (g)"", " &  _
                      wb.Worksheets(1).Range("A18:F28").address(External:=true) & _
                      ", 2, FALSE)"

Answer 2

For the formula, you need to add the name of the workbook into the string. You can't reference the variable wb while it is part of the string. You also need to reference the workbook and the sheet name.

So I'd suggest something like the following to get those names:

ActiveCell.FormulaR1C1 = "=VLOOKUP(""Sugar (g)"",[" & wb.name & "]" & wb.Worksheet(1).Name & "!R18C1:R28C6,2,FALSE)"

Answer 3

What I do in these kinds of situations is keep removing parts of code until it works or gives a different error message or something. That way you can narrow down to where the error is.

The Do While .. Loop looks fine, I think you're missing an End If

If Right(wb.Name, 5) = "h.xls" Then
  wb.Worksheets(1).Range("B16").Select
  ActiveCell.Value = Left(wb.Name, 9)
End If