记录宏所做的更改的最快方法

Question

Some background:

I have an Excel Add-In that executes 17 Sub Routines and was wondering what would be the easiest, most efficient, and fastest way to

1. Record specific changes made by the macro
2. Display a list of all the changes (in a new spreadsheet) and why it changed (or flagged/highlighted) each cell
3. Provide the cell address of each error as a clickable link that will take the user to the specific cell in another worksheet (in the same workbook)

What I've gathered thus far:

I've read up on a few methods of how to accomplish this, most notably from here , here , here , and most importantly here . These suggest methods such as

• Dumping the UsedRange into an array prior to running through all the subs, then dumping the UsedRange into a second array after all the subs have completed. Compare the two arrays and find the differences that way.
• Utilizing the worksheet_change event to log the changes.
• The last link for the Marktastic site provides the most convincing method, combining the previous two methods. However, even with his method of checking the array each time the worksheet_change event fires takes .06 seconds, which seems like it will add up to a lot of overhead.

A few particular issues I face include:

• Dealing with large files (15000+ rows, 150 columns)
• Some of my subs make changes that don't need to be noted, such as only rearranging values in certain cells, not changing them otherwise
• My macro is built to work fast (<1 minute) and complete it's scan of our large files, so I imagine this would eliminate using the Worksheet_Change event and also writing immediately to the separate worksheet after each error is addressed accordingly. Even utilizing both methods in one as Mark suggests seems like it'll cause too much lagtime.
• Comparing two arrays appears it would also be quite slow for files as large as I'm working with, as it would mean iterating through 15000 (rows) x 150 (columns) = 2,250,000 cells
• Since I"m making all the changes via a macro the worksheet_change event won't fire.

So, that basically eliminates all of the options I've come across. The only other option I can think of is just have one array, use it to record the cell/location and the error in the location as the code is executing and then dump the entire array into the new sheet after the subs complete. Would this really be my best option though?

So, given all of the facts and research above

Now, for my question:

• What would be the most efficient way in my situation to record changes and show what (necessary-to-note) changes have been made to the file after my macro has completed? Whether I've listed it or not, feel free to share a method you feel would best suit this situation.
• Can you provide a simple sample code of how to implement your suggested method?

Answer 1

Here's what I've decided to go with. Using this method I call a sub each time I want to note a change and pass the necessary variables that I need recorded. In this case, Cell , Reason , Status . Then the sub that has been called stores it at the end of a public Array , in this case ChangeLog . After I am finished recording all of the changes I need I call the PrintLog sub to spit out the list of changes onto a new sheet, which I rename Change Log . A neat addition I added was the pre-made HYPERLINK formulas I produce while storing the values inside the array. Once the array is pasted to the worksheet the cell references are already clickable links that bring the user to the address on the other worksheet.

Public ChangeLog() As String

Sub Test()
    Log ActiveSheet.Range("A2"), "Test1", "Changed"
    Log ActiveSheet.Range("B2"), "Test2", "Needs Attention"
    Log ActiveSheet.Range("C2"), "Test3", "Changed"
    PrintLog
End Sub

Sub Log(Cell As Range, Reason As String, Optional Status As String)
    On Error Resume Next
    If (Not Not ChangeLog) = 0 Then
        ReDim ChangeLog(0 To 2, 0 To 1)
        ChangeLog(0, 0) = "Cells": ChangeLog(1, 0) = "Changes Made": ChangeLog(2, 0) = "Status"
        ChangeLog(0, 1) = "=Hyperlink(" & """#'" & ActiveSheet.Name & "'!" & Cell.Address(False, False) & """,""" & Cell.Address(False, False) & """)"
        ChangeLog(1, 1) = Reason
        ChangeLog(2, 1) = Status
    Else
        ReDim Preserve ChangeLog(0 To 2, 0 To UBound(ChangeLog, 2) + 1)
        ChangeLog(0, UBound(ChangeLog, 2)) = "=Hyperlink(" & """#'" & ActiveSheet.Name & "'!" & Cell.Address(False, False) & """,""" & Cell.Address(False, False) & """)"
        ChangeLog(1, UBound(ChangeLog, 2)) = Reason
        ChangeLog(2, UBound(ChangeLog, 2)) = Status
    End If
    On Error GoTo 0
End Sub

Sub PrintLog()
    Dim currentSheet As Integer: currentSheet = ActiveSheet.Index
    For s = 1 To ActiveWorkbook.Worksheets.Count
        If Worksheets(s).Name = "Change Log" Then
            Application.DisplayAlerts = False
            Worksheets(s).Delete
            Application.DisplayAlerts = True
            Exit For
        End If
    Next
    Dim WS As Worksheet: Set WS = Sheets.Add(After:=Worksheets(ActiveSheet.Index))
    WS.Name = "Change Log"
    WS.Tab.Color = vbYellow
    WS.Range("A1").Resize(UBound(ChangeLog, 2) + 1, 3) = WorksheetFunction.Transpose(ChangeLog)
    Erase ChangeLog
    Worksheets(currentSheet).Activate
End Sub

Change Log Sheet Preview: