XSLT中先前节点的总和作为当前节点的值

Question

I am trying to obtain the target xml such that value of a node is comma seperated values of sum of previous similar node values. For eg:

Input:

<Items>
  <Item>
    <name>Drakshi</name>
    <price>50</price>
  </Item>
  <Item>
    <name>Godambi</name>
    <price>30</price>
  </Item>
  <Item>
    <name>Badami</name>
    <price>70</price>
  </Item>
</Items>

Output:

<result>
 50,80,150
</result>

As you can see above it is 50, (50+30), (50+30+70)

I tried with for-each Item and was able to find the sum of only current node and previous selected node. Can you please guide me here

Answer 1

Try something like this:

<xsl:template match="Items">
  <result>
    <xsl:for-each select="Item">
      <xsl:value-of select="sum(preceding-sibling::Item/price | price) " />
      <xsl:if test="position() != last()">, </xsl:if>
    </xsl:for-each>
  </result>
 </xsl:template>

Answer 2

While you could use sum(preceding-sibling::...) a more efficient solution would use a recursive template to accumulate the sum one value at a time:

<xsl:template match="/Items">
    <result>
        <xsl:call-template name="run-total">
            <xsl:with-param name="values" select="Item/price"/>
        </xsl:call-template>
    </result>
</xsl:template>

<xsl:template name="run-total">
    <xsl:param name="values"/> 
    <xsl:param name="i" select="1"/> 
    <xsl:param name="total" select="0"/> 
    <xsl:variable name="balance" select="$total + $values[$i]" />
    <xsl:value-of select="$balance" />
    <xsl:if test="$i &lt; count($values)">
        <xsl:text>,</xsl:text>
        <xsl:call-template name="run-total">
            <xsl:with-param name="values" select="$values"/>
            <xsl:with-param name="i" select="$i + 1"/>
            <xsl:with-param name="total" select="$balance"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

Answer 3

If you want to solve it with XSLT 2.0 then I don't think you need any user defined function, you can write a single XPath 2.0 expression:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="2.0">

<xsl:template match="Items">
    <result>
        <xsl:value-of 
            select="for $pos in 1 to count(Item)
                    return sum(subsequence(Item, 1, $pos)/price)"
            separator=","/>
    </result>
</xsl:template>

</xsl:stylesheet>

Answer 4

Thanks for the replies. I followed this approach which worked for me:

<xsl:function name="kk:getSumTillIndex">
    <xsl:param name="index"/>     
    <xsl:variable name="Var_PriceArray" select="$Items/item[position()&lt;=$index]//price/text()"/>
    <xsl:for-each select="$Var_PriceArray">
        <Item>
            <xsl:value-of select="current()"/>
        </Item>
    </xsl:for-each>
</xsl:function>


<xsl:function name="kk:calulatePriceSequence">
    <xsl:variable name="set" select="$Items/Item" />
    <xsl:variable name="count" select="count($set)" />

    <xsl:for-each select="$set">
         <xsl:if test="position() &lt;= $count">
         <xsl:value-of select="sum(kk:getSumTillIndex(position()))"/>

            <xsl:if test="position() &lt; number($count)-1">
                <xsl:value-of select="','" />
            </xsl:if>   
        </xsl:if>
        </xsl:for-each>
</xsl:function>