如何在文本文件中提取路径并在VBA中使用它？

Question

as a beginner , i have been with this problem 2 days and i am desperate for your help .

My text file is :

C:\Sourcefile\imported
C:\Destination\not imported
C:\Testexcel\test.xlxs

and i need to read the text and use these path in vba . The object of the vba code is to create a new folder if it not existe in the destination .

FSO = CreateObject("Scripting.FileSystemObject")
set oSourceFolder=FSO.getfolder(Line1,Readline)  'if i replace line with the path it will work
set oSourceFolder=FSO.getfolder(Line2,Readline)
set oSourceFolder=FSO.getfolder(Line3,Readline)

if dir("C:\Destination\not imported",16)="" Then Mkdir (":\Destination\not imported")

Here , i want to replace the path with the line but it is not working .

Can you help me please ?

Answer 1

you must

• add Set keyword at the beginning of

FSO = CreateObject("Scripting.FileSystemObject" )

• use ReadLine method of TextStream object to retrieve every single line of the text file into a string object

• parse that string returned for possible files specification and get only their its path part

• use FolderExists method of FileSystemObject object to check for existing folders

• and finally get (if existent) that folder or create (if non existent) it via GetFolder or CreateFolder methods of FileSystemObject object

much like follows:

---

     Option Explicit

     Sub main()
        Dim FSO As FileSystemObject
        Dim foldersListFile As TextStream
        Dim folderName As String
        Dim oSourceFolder As Folder

        Set FSO = CreateObject("Scripting.FileSystemObject")

        Set foldersListFile = FSO.OpenTextFile("C:\myPath\folders.txt", ForReading, TristateFalse)

        Do While Not foldersListFile.AtEndOfStream
             folderName = GetFolderStringOnly(foldersListFile.ReadLine)

             If FSO.FolderExists(folderName) Then
                 Set oSourceFolder = FSO.GetFolder(folderName)
             Else
                 Set oSourceFolder = FSO.CreateFolder(folderName)
             End If
           Loop

        foldersListFile.Close

     End Sub

     Function GetFolderStringOnly(textLine As String) As String
         Dim iDot As Long, iSlash As Long
         iDot = InStrRev(textLine, ".")
         If iDot > 0 Then
             iSlash = InStrRev(Left(textLine, iDot), "\")
             textLine = Left(textLine, iSlash - 1)
         End If
         GetFolderStringOnly = textLine
     End Function