如何使用VBA获取文本框中的浏览文件路径？

Question

How to get the browse file name into text box ? if get the file path, how to split the file name?

I tried application.GetOpenFilename("Text Files(*.txt),*.txt")

Please advise to display into the text box and how to split the exact file name only to read the text file?

Answer 1

Don't waste your time reinventing the wheel: the FileSystemObject will do this for you.

Dim FSO As Object: Set FSO = CreateObject("Scripting.FileSystemObject")
Sheet1.TextBox1.Text = FSO.GetFilename("C:\mydir\myfile.dat")

The textbox now contains the text myfile.dat .

Answer 2

The Dir function will give you the file name as long as it's a file that exists - and yours will be if you use GetOpenFilename.

Sub GetFileName()

    Dim sFullName As String
    Dim sFileName As String

    sFullName = Application.GetOpenFilename("*.txt,*.txt")
    sFileName = Dir(sFullName)

    Debug.Print sFullName, sFileName

End Sub

Answer 3

Here is a VBA routine to return the file name stripped of its path. Its easily modified to return the path instead, or both.

'====================================================================================
'     Returns the file name without a path via file open dialog box
'====================================================================================
' Prompts user to select a file.  Which ever file is selected, the function returns
' the filename stripped of the path.

Function GetAFileName() As String

Dim someFileName As Variant
Dim folderName As String
Dim i As Integer
Const STRING_NOT_FOUND As Integer = 0

'select a file using a dialog and get the full name with path included
someFileName = Application.GetOpenFilename("Text Files (*.txt), *.txt")

If someFileName <> False Then

    'strip off the folder path
    folderName = vbNullString
    i = 1

    While STRING_NOT_FOUND < i
        i = InStr(1, someFileName, "\", vbTextCompare)  'returns position of the first backslash "\"
        If i <> STRING_NOT_FOUND Then
            folderName = folderName & Left(someFileName, i)
            someFileName = Right(someFileName, Len(someFileName) - i)
        Else 'no backslash was found... we are done
            GetAFileName = someFileName

        End If
    Wend

Else
    GetAFileName = vbNullString
End If

End Function

Answer 4

最简单的方法是简单地从最后的"\\"读取内容；

tbx.text = mid$(someFileName, 1 + InStrRev(someFileName, "\"), Len(someFileName))

Answer 5

Button1 click

    OpenFileDialog1.ShowDialog()
    Me.TextBox1.Text = OpenFileDialog1.FileName
End Sub

Textbox1 change

    Dim File As System.IO.FileInfo
    File = My.Computer.FileSystem.GetFileInfo(TextBox1.Text)
    Dim Path As String = File.DirectoryName
    TextBox2.Text = Path
    Dim fileName As String = File.Name
    TextBox3.Text = fileName
End Sub