Delphi 创建一个包中的框架

Question

today I've a question about frames that are in packages. I've a package that contains a simple frame:

unit fraMain;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.StdCtrls;

type

  TFrame1 = class(TFrame)
    Label1: TLabel;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

implementation

{$R *.dfm}

initialization
  RegisterClass(TFrame1);

finalization
  UnRegisterClass(TFrame1);

end.

I've create the package and a new projexct that use it. The project has a simple form and it's code is this:

unit main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.Menus,
  System.Actions, Vcl.ActnList, Vcl.PlatformDefaultStyleActnCtrls, Vcl.ActnMan,
  Vcl.StdCtrls;

type
  TfrmMain = class(TForm)
    mnuMain: TMainMenu;
    mnuFile: TMenuItem;
    mnuModuli: TMenuItem;
    mFilCloseModules: TMenuItem;
    mModModulo1: TMenuItem;
    mModModulo2: TMenuItem;
    N1: TMenuItem;
    mFilExit: TMenuItem;
    actManager: TActionManager;
    actExit: TAction;
    actModulo1: TAction;
    actModulo2: TAction;
    procedure actExitExecute(Sender: TObject);
    procedure actModulo1Execute(Sender: TObject);
  private
    FPackageHandle: Integer;
  public
    { Public declarations }
  end;

const
  DIRPACK1 = 'C:\Users...';

var
  frmMain: TfrmMain;

implementation

{$R *.dfm}


{ Chiusura applicazione }
procedure TfrmMain.actExitExecute(Sender: TObject);
begin
  Application.Terminate;
end;

procedure TfrmMain.actModulo1Execute(Sender: TObject);
var
  AClass: TClass;
  AFrame: TFrame;
begin
  if FPackageHandle = 0 then begin
    FPackageHandle := LoadPackage(DIRPACK1 + 'Pack_01.bpl');
    AClass := GetClass('TFrame1');
    if AClass <> nil then begin

    end;
  end;
end;

end.

Where DIRPACK1 is the path of where the bpl is. In the "actModulo1Execute" action I would like to create the frame. As you can see I get the class, but after I don't know how to instantiate the frame. Which is the manner for create the frame?

Answer 1

For example:

  AClass := GetClass('TFrame1');
  if Assigned(AClass) and AClass.InheritsFrom(TCustomFrame) then
  begin
    AFrame := TCustomFrameClass(AClass).Create(Self);
    AFrame.Parent := Self;
    AFrame.Align := alClient;
    AFrame.Show;
  end;

If you don't want to use RegisterClass then another possible way is this:

  AClass := GetProcAddress(FPackageHandle, '@fraMain@TFrame1@');

(the convention is <at><unit_name><at><class_name><at> ).