Excel UDF适用于整个范围而不是每个单元格

Question

I have the following UDFs in my workbook:

Function GetRoundTime(Shp1 As String, Res1 As String, Shp2 As String, Res2 As String, Sht As String) As String
    Dim i As Long
    Dim TempSheet As Worksheet
    Set TempSheet = Workbooks("odds_datalog.xlsm").Worksheets(Sht)
    'Need to find out what the last row is instead of hardcoding it at 2000
    For i = 2 To 2000
        If TempSheet.Cells(i, "D").Value = Shp1 And TempSheet.Cells(i, "I").Value = Shp2 And TempSheet.Cells(i, "E").Value = Res1 And TempSheet.Cells(i, "J").Value = Res2 Then
            GetRoundTime = CStr(TempSheet.Cells(i, "K").Value)
            Exit Function
        End If
    Next i
    GetRoundTime = "Failed"
End Function


Function GetOdds(Shp1 As String, Res1 As String, Sht1 As String, Shp2 As String, Res2 As String, Sht2 As String) As String
    Dim LeftTime As String
    Dim TopTime As String
    LeftTime = GetRoundTime(Shp1, Res1, Shp2, Res2, Sht1)
    TopTime = GetRoundTime(Shp2, Res2, Shp1, Res1, Sht2)
    If LeftTime = "NoAttack" Then
        GetOdds = ""
    ElseIf LeftTime = "TimedOut" Then
        GetOdds = "Time (left)"
    ElseIf LeftTime = "SameShip" Then
        GetOdds = ""
    ElseIf LeftTime = "Failed" Then
        GetOdds = "Failed"
    ElseIf TopTime = "NoAttack" Then
        GetOdds = ""
    ElseIf TopTime = "TimedOut" Then
        GetOdds = "Time (top)"
    ElseIf TopTime = "SameShip" Then
        GetOdds = ""
    ElseIf TopTime = "Failed" Then
        GetOdds = "Failed"
    Else
        GetOdds = Sqr(Val(TopTime) / Val(LeftTime))
    End If
End Function

And, the GetOdds function is called in every cell like this:

=GetOdds($A20,$B20,"log_hgn_hgn",D$1,D$2,"log_hgn_hgn")
=GetOdds($A21,$B21,"log_hgn_hgn",D$1,D$2,"log_hgn_hgn")
=GetOdds($A22,$B22,"log_hgn_hgn",D$1,D$2,"log_hgn_hgn")

And so on.

However, the recalculation is very slow. I heard that inputting a range of cells speeds up performance. Is this true? How would I alter the code to do this? Thanks!

[edit]

Here's what one of the worksheets looks like.

http://imgur.com/a/XMoiS

Answer 1

I'm not sure exactly what you mean by "inputting a range of cells", but the slowest part of your function is here:

'Need to find out what the last row is instead of hardcoding it at 2000
For i = 2 To 2000
    If TempSheet.Cells(i, "D").Value = Shp1 And TempSheet.Cells(i, "I").Value = Shp2 And TempSheet.Cells(i, "E").Value = Res1 And TempSheet.Cells(i, "J").Value = Res2 Then
        GetRoundTime = CStr(TempSheet.Cells(i, "K").Value)
        Exit Function
    End If
Next i

You are repeatedly accessing the Worksheet, and that is slow . You'll likely get your biggest performance gain by pulling all of the values into an array at once and using the array instead. Something like this should speed it up significantly:

Function GetRoundTime(Shp1 As String, Res1 As String, Shp2 As String, _
                      Res2 As String, Sht As String) As String
    With Workbooks("odds_datalog.xlsm").Worksheets(Sht)
        Dim lastRow As Long, values() As Variant
        lastRow = .Range("A" & .Rows.Count).End(xlUp).Row
        values = .Range(.Cells(2, 4), .Cells(lastRow, 11)).Value
        Dim i As Long
        For i = 1 To lastRow - 1
            If values(i, 1) = Shp1 And values(i, 6) = Shp2 And _ 
               values(i, 2) = Res1 And values(i, 7) = Res2 Then
                GetRoundTime = CStr(values(i, 8))
                Exit Function
            End If
        Next
    End With
    GetRoundTime = "Failed"
End Function