如何从Delphi中的文本文件中删除特定行

Question

I have a text file with user information stored in it line by line. Each line is in the format: UserID#UserEmail#UserPassword with '#' being the delimiter.

I have tried to use this coding to perform the task:

var sl:TStringList;
begin
  sl:=TStringList.Create;
  sl.LoadFromFile('filename');
  sl.Delete(Index);
  sl.SaveToFile('filename');
  sl.free;
end;

But I'm not sure what to put in the "index" space.

Is there any way I can receive the User ID as input and then delete the line of text from the text file that has this user ID in? Any help would be appreciated.

Answer 1

You can set the NameValueSeparator to # then use IndexOfName to find the user, as long as the username is the first value in the file.

sl.NameValueSeparator := '#';
Index := sl.IndexOfName('455115')

So in your example, like so

var sl:TStringList;
begin
  sl:=TStringList.Create;
  sl.LoadFromFile('filename');
  sl.NameValueSeparator := '#';
  Index := sl.IndexOfName('455115')
  if (Index  <> -1) then
  begin
      sl.Delete(Index);
      sl.SaveToFile('filename');
  end;
  sl.free;
end;

This may be slow on large files as IndexOfName loops though each line in the TStringList and checks each string in turn until it finds a match.

Disclaimer: Tested/ works with Delphi 2007, Delphi 7 may be diffrent.

Answer 2

I don't see why so many people make this so hard. It is quite simple:

function ShouldDeleteLine(const UserID, Line: string): Boolean;
begin    
  // Remember: Pos(Needle, Haystack)
  Result := Pos(UserID + '#', Line) = 1; // always 1-based!
end;

procedure DeleteLinesWithUserID(const FileName, UserID: string);
var
  SL: TStringList;
  I: Integer;
begin
  if not FileExists(FileName) then
    Exit;

  SL := TStringList.Create;
  try
    SL.LoadFromFile(FileName); // Add exception handling for the 
                               // case the file does not load properly.

    // Always work backward when deleting items, otherwise your index
    // may be off if you really delete.
    for I := SL.Count - 1 downto 0 do
      if ShouldDeleteLine(SL[I], UserID) then
      begin
        SL.Delete(I);
        // if UserID is unique, you can uncomment the following line.
        // Break;
      end;
    SL.SaveToFile(FileName);
  finally
    SL.Free;
  end;
end;

As Arioch'The says, if you save to the same file name, you risk losing your data when the save fails, so you can do something like

SL.SaveToFile(FileName + '.dup');
if FileExists(FileName + '.old') then
  DeleteFile(FileName + '.old');
RenameFile(FileName, FileName + '.old');
RenameFile(FileName + '.dup', FileName);

That keeps a backup of the original file as FileName + '.old' .

Explanations

Working backward

Why work backward? Because if you have the following items

A B C D E F G
      ^

And you delete the item at ^ , then the following items will shift downward:

A B C E F G
      ^

If you iterate forward, you will now point to

A B C E F G
        ^

and E is never examined. If you go backward, then you will point to:

A B C E F G
    ^

Note that E , F and G were examined already, so now you will indeed examine the next item, C , and you won't miss any. Also, if you go upward using 0 to Count - 1 , and delete, Count will become one less and at the end, you will try to access past the boundary of the list. This can't happen if you work backwards using Count - 1 downto 0 .

Using + '#'

If you append '#' and test for Pos() = 1 , you will be sure to catch the entire UserID up to the delimiter, and not a line with a user ID that only contains the UserID you are looking for. IOW, if UserID is 'velthuis' , you don't want to delete lines like 'rudyvelthuis#rvelthuis01#password' or 'velthuisresidence#vr#password2' , but you do want to delete 'velthuis#bla#pw3' .

Eg when looking for a user name, you look for '#' + UserName + '#' for the same reason.

Answer 3

There is the only way to actually "delete a line from the text file" - that is to create a new file with changed content, to REWRITE it.

So you better just do it explicitly.

And don't you forget about protecting from errors. Your current code might just destroy the file and leak memory, if any error occurs...

var sl: TStringList;
    s, prefix: string;
    i: integer; okay: Boolean;
    fs: TStream;

begin
  prefix := 'UserName' + '#';
  okay := false;

  fs := nil;
  sl:=TStringList.Create;
  Try   /// !!!!
    sl.LoadFromFile('filename');
    fs := TFileStream.Create( 'filename~new', fmCreate or fmShareExclusive );

    for i := 0 to Prev(sl.Count) do begin
      s := sl[ i ];

      if AnsiStartsStr( prefix, Trim(s) ) then
         continue;  // skip the line - it was our haunted user

      s := s + ^M^J;  // add end-of-line marker for saving to file

      fs.WriteBuffer( s[1], length(s)*SizeOf(s[1]) );  
    end; 
  finally 
    fs.Free;
    sl.Free;
  end;

  // here - and only here - we are sure we successfully rewritten 
  // the fixed file and only no are able to safely delete old file
  if RenameFile( 'filename' , 'filename~old') then
     if RenameFile( 'filename~new' , 'filename') then begin
        okay := true; 
        DeleteFile( 'filename~old' ); 
     end;

  if not okay then ShowMessage(' ERROR!!! ');
end;

Note 1: See if check for username should be case-sensitive or case-ignoring:

• http://www.freepascal.org/docs-html/rtl/strutils/ansistartsstr.html
• http://www.freepascal.org/docs-html/rtl/strutils/ansistartstext.html

Note 2: in Delphi 7 SizeOf( s[1] ) is always equal to one because string is an alias to AnsiString . But in newer Delphi version it is not. It might seems tedious and redundant - but it might save a LOT of headache in future. Even better would be to have a temporary AnsiString type variable like a := AnsiString( s + ^m^J ); fs.WriteBuffer(a[1],Length(a)); a := AnsiString( s + ^m^J ); fs.WriteBuffer(a[1],Length(a));

Answer 4

So far everyone has been suggesting the use for a For..Then Loop but can I suggest a Repeat..While .

The traditional For..Loop is a good option but could be inefficient if you have a long list of Usernames (they are usually unique). Once found and deleted the For Loop continues until the end of the list. That's ok if you have a small list but if you have 500,000 Usernames and the one you want is at position 10,000 there is no reason to continue beyond that point.

Therefore, try this.

    Function DeleteUser(Const TheFile: String; Const TheUserName: String): Boolean;
    Var
      CurrentLine: Integer;
      MyLines: TStringlist;
      Found: Boolean;
      Eof: Integer;

    Begin

      MyLines := TStringlist.Create;
      MyLines.LoadFromFile(TheFile);

      CurrentLine := 0;
      Eof := Mylines.count - 1; 

      Found := false;

      Repeat 

        If Pos(UpperCase(TheUserName), UpperCase(MyLines.Strings[CurrentLine])) = 1 Then
        Begin

         MyLines.Delete(CurrentLine);
          Found := True;

        End;

        Inc(CurrentLine);

      Until (Found) Or (CurrentLine = Eof); // Jump out when found or End of File

      MyLines.SaveToFile(TheFile);
      MyLines.Free;

      result := Found;
    End;

Once called the function returns True or False indicating the Username was deleted or not.

If Not DeleteUsername(TheFile,TheUsername) then
ShowMessage('User was not found, what were you thinking!');

Answer 5

Just for fun, here's a compact solution, which I like for its readability.

const fn = 'myfile.txt';

procedure DeleteUser(id: integer);
var s:string; a:TStringDynArray;
begin
  for s in TFile.ReadAllLines(fn) do
    if not s.StartsWith(id.ToString + '#') then
      a := a + [s];

  TFile.WriteAllLines(fn, a);
end;

Obviously it's not the most efficient solution. This could run faster by not appending single items to the array, or by caching the search string.

And to search for other fields, you could use s.split(['#'])[0] to find the username, s.split(['#'])[1] for email, etc.

Answer 6

For those who like one-liners. This works too:

const fn = 'users.txt';

procedure DeleteUserRegExp(id: string);
begin
  TFile.WriteAllText(fn,TRegEx.Replace(TFile.ReadAllText(fn),''+id+'\#.*\r\n',''))
end;

Explanation

1. It loads the content of a file into a string.
2. The string is sent to TRegEx.Replace
3. The regular expression searches for the username followed by the hash sign, then any character, and then a CRLF. It replaces it with an empty string.
4. The resulting string is then written to the original file

This is just for fun though, because I saw long code where I thought that this would be possible with a single line of code.