如何从Delphi中的文本文件中删除特定行

Question

我有一个文本文件，其中逐行存储了用户信息。 每行的格式为： UserID#UserEmail#UserPassword其中'＃'为分隔符。

我试图使用此编码来执行任务：

var sl:TStringList;
begin
  sl:=TStringList.Create;
  sl.LoadFromFile('filename');
  sl.Delete(Index);
  sl.SaveToFile('filename');
  sl.free;
end;

但我不确定在“索引”空间放什么。

有什么方法可以接收用户ID作为输入，然后从具有此用户ID的文本文件中删除文本行？ 任何帮助，将不胜感激。

Answer 1

您可以将NameValueSeparator设置为#然后使用IndexOfName查找用户，只要用户名是文件中的第一个值即可。

sl.NameValueSeparator := '#';
Index := sl.IndexOfName('455115')

所以在你的例子中，就像这样

var sl:TStringList;
begin
  sl:=TStringList.Create;
  sl.LoadFromFile('filename');
  sl.NameValueSeparator := '#';
  Index := sl.IndexOfName('455115')
  if (Index  <> -1) then
  begin
      sl.Delete(Index);
      sl.SaveToFile('filename');
  end;
  sl.free;
end;

对于大型文件，这可能会很慢，因为IndexOfName会循环访问TStringList中的每一行，并依次检查每个字符串，直到找到匹配项为止。

免责声明：测试/使用Delphi 2007，Delphi 7可能不同。

Answer 2

我不明白为什么这么多人如此努力。 这很简单：

function ShouldDeleteLine(const UserID, Line: string): Boolean;
begin    
  // Remember: Pos(Needle, Haystack)
  Result := Pos(UserID + '#', Line) = 1; // always 1-based!
end;

procedure DeleteLinesWithUserID(const FileName, UserID: string);
var
  SL: TStringList;
  I: Integer;
begin
  if not FileExists(FileName) then
    Exit;

  SL := TStringList.Create;
  try
    SL.LoadFromFile(FileName); // Add exception handling for the 
                               // case the file does not load properly.

    // Always work backward when deleting items, otherwise your index
    // may be off if you really delete.
    for I := SL.Count - 1 downto 0 do
      if ShouldDeleteLine(SL[I], UserID) then
      begin
        SL.Delete(I);
        // if UserID is unique, you can uncomment the following line.
        // Break;
      end;
    SL.SaveToFile(FileName);
  finally
    SL.Free;
  end;
end;

正如Arioch所说，如果你保存到相同的文件名，你可能会在保存失败时丢失数据，所以你可以做类似的事情

SL.SaveToFile(FileName + '.dup');
if FileExists(FileName + '.old') then
  DeleteFile(FileName + '.old');
RenameFile(FileName, FileName + '.old');
RenameFile(FileName + '.dup', FileName);

这使原始文件的备份保持为FileName + '.old' 。

说明

向后工作

为什么要倒退？ 因为如果你有以下物品

A B C D E F G
      ^

并且您在^处删除该项目，然后以下项目将向下移动：

A B C E F G
      ^

如果你向前迭代，你现在将指向

A B C E F G
        ^

从未检查过E 如果你倒退，那么你会指出：

A B C E F G
    ^

请注意， E ， F和G已经被检查过了，所以现在你确实会检查下一个项目C ，你不会错过任何一个。 此外，如果向上使用0 to Count - 1 ，并且删除， Count将减少一个，最后，您将尝试访问列表的边界。 如果您使用Count - 1 downto 0向后工作，则不会发生这种情况。

使用+ '#'

如果附加'#'并测试Pos() = 1 ，您将确保将整个UserID捕获到分隔符，而不是具有仅包含您要查找的UserID的用户ID的行。 IOW，如果UserID是'velthuis' ，你不想删除像'rudyvelthuis#rvelthuis01#password'或'velthuisresidence#vr#password2' ，但你确实要删除'velthuis#bla#pw3' 。

例如，在查找用户名时，出于同样的原因，您会查找'#' + UserName + '#' 。

Answer 3

有唯一的方法来实际“从文本文件中删除一行” - 即创建一个具有更改内容的新文件，以REWRITE它。

所以你最好明确地做。

你不要忘记防止错误。 如果发生任何错误，您当前的代码可能只会破坏文件并泄漏内存...

var sl: TStringList;
    s, prefix: string;
    i: integer; okay: Boolean;
    fs: TStream;

begin
  prefix := 'UserName' + '#';
  okay := false;

  fs := nil;
  sl:=TStringList.Create;
  Try   /// !!!!
    sl.LoadFromFile('filename');
    fs := TFileStream.Create( 'filename~new', fmCreate or fmShareExclusive );

    for i := 0 to Prev(sl.Count) do begin
      s := sl[ i ];

      if AnsiStartsStr( prefix, Trim(s) ) then
         continue;  // skip the line - it was our haunted user

      s := s + ^M^J;  // add end-of-line marker for saving to file

      fs.WriteBuffer( s[1], length(s)*SizeOf(s[1]) );  
    end; 
  finally 
    fs.Free;
    sl.Free;
  end;

  // here - and only here - we are sure we successfully rewritten 
  // the fixed file and only no are able to safely delete old file
  if RenameFile( 'filename' , 'filename~old') then
     if RenameFile( 'filename~new' , 'filename') then begin
        okay := true; 
        DeleteFile( 'filename~old' ); 
     end;

  if not okay then ShowMessage(' ERROR!!! ');
end;

注1：查看用户名检查是区分大小写还是忽略大小写：

• http://www.freepascal.org/docs-html/rtl/strutils/ansistartsstr.html
• http://www.freepascal.org/docs-html/rtl/strutils/ansistartstext.html

注2：在Delphi 7中， SizeOf( s[1] )总是等于1，因为string是AnsiString的别名。 但在较新的Delphi版本中却没有。 这可能看起来很乏味和多余 - 但它可能会在未来挽救很多头痛。 更好的是拥有一个临时的AnsiString类型变量，如a := AnsiString( s + ^m^J ); fs.WriteBuffer(a[1],Length(a)); a := AnsiString( s + ^m^J ); fs.WriteBuffer(a[1],Length(a));

Answer 4

到目前为止，每个人都建议使用For..Then循环，但是我可以建议重复...而不是 。

传统的For..Loop是一个不错的选择，但如果你有很长的用户名列表（它们通常是唯一的），效率可能会很低。 一旦找到并删除， For循环将继续，直到列表结束。 如果你有一个小的列表，但如果你有500,000个用户名，而你想要的那个位于10,000，那么没有理由继续超过这一点。

因此，试试这个。

    Function DeleteUser(Const TheFile: String; Const TheUserName: String): Boolean;
    Var
      CurrentLine: Integer;
      MyLines: TStringlist;
      Found: Boolean;
      Eof: Integer;

    Begin

      MyLines := TStringlist.Create;
      MyLines.LoadFromFile(TheFile);

      CurrentLine := 0;
      Eof := Mylines.count - 1; 

      Found := false;

      Repeat 

        If Pos(UpperCase(TheUserName), UpperCase(MyLines.Strings[CurrentLine])) = 1 Then
        Begin

         MyLines.Delete(CurrentLine);
          Found := True;

        End;

        Inc(CurrentLine);

      Until (Found) Or (CurrentLine = Eof); // Jump out when found or End of File

      MyLines.SaveToFile(TheFile);
      MyLines.Free;

      result := Found;
    End;

一旦被调用，该函数返回True或False，表示用户名已被删除。

If Not DeleteUsername(TheFile,TheUsername) then
ShowMessage('User was not found, what were you thinking!');

Answer 5

只是为了好玩，这是一个紧凑的解决方案，我喜欢它的可读性。

const fn = 'myfile.txt';

procedure DeleteUser(id: integer);
var s:string; a:TStringDynArray;
begin
  for s in TFile.ReadAllLines(fn) do
    if not s.StartsWith(id.ToString + '#') then
      a := a + [s];

  TFile.WriteAllLines(fn, a);
end;

显然，这不是最有效的解决方案。 通过不向数组附加单个项目或通过缓存搜索字符串，可以更快地运行。

要搜索其他字段，您可以使用s.split(['#'])[0]查找用户名， s.split(['#'])[1]用于发送电子邮件等。

Answer 6

对于那些喜欢单行的人。 这也有效：

const fn = 'users.txt';

procedure DeleteUserRegExp(id: string);
begin
  TFile.WriteAllText(fn,TRegEx.Replace(TFile.ReadAllText(fn),''+id+'\#.*\r\n',''))
end;

说明

1. 它将文件的内容加载到字符串中。
2. 该字符串被发送到TRegEx.Replace
3. 正则表达式搜索用户名，后跟哈希符号，然后搜索任何字符，然后搜索CRLF。 它用空字符串替换它。
4. 然后将生成的字符串写入原始文件

这只是为了好玩，因为我看到了很长的代码，我认为这可以用一行代码实现。