下标超出范围错误9 vba

Question

I am getting a subscript out of range error when another user runs my add in but have no problems when running the same code myself. This happens when setting a workbook value. The filename is being generated by getting the current date and stored as gendate. From this, the filename is created and saved based on the filepath that the user has made. In this example, the value of gv.Range("b2").text is C:\\Users\\username\\Desktop\\ReportGeneration. fp is therefore C:\\Users\\dmulhausen\\Desktop\\ReportGeneration\\TSReports9_6_201615h5m32s.xlsx This is not generating an error for me, but it is generating an error for another user of the script.

Dim ai As Workbook  'add in data ---Initialized in Report Setup
Dim dwb As Workbook 'destination workbook ---Initialized in Report Setup
Dim ss As Worksheet 'source sheet
Dim ds As Worksheet 'destination sheet or writing sheet
Dim rv As Worksheet 'reporting variables sheet ---Initialized in Report Setup
Dim pv As Worksheet 'ts variables sheet ---Initialized in Report Setup
Dim gv As Worksheet 'global ai variables ---Initialized in Report Setup
Dim tempstr As String
Dim fp As String 'file path ---Initialized in Report Setup
Dim gendate As Date
Dim reportscreated As Integer
Dim initialized As Boolean
Dim sheetnames(1 To 12) As String

Sub reportsetup()
    Set ai = Workbooks("TSReports add in.xlam")
    Set rv = ai.Worksheets("ReportVars")
    Set pv = ai.Worksheets("TS1_2Vars")
    Set gv = ai.Worksheets("globalVars")
    If (IsEmpty(gv.Range("b2").Value)) Then
        MsgBox ("Please select a designated folder for reports")
        With Application.FileDialog(msoFileDialogFolderPicker)
            .AllowMultiSelect = False
            .Show
            If .SelectedItems.Count > 0 Then
                gv.Range("b2").Value = .SelectedItems(1)
            End If
            ai.Save
        End With

    End If
    initialized = True
    gendate = Now()
    tempstr = "TSReports" & Month(gendate) & "_" & Day(gendate) & "_" & Year(gendate) & Hour(gendate) & "h" & Minute(gendate) & "m" & Second(gendate) & "s"
    fp = gv.Range("b2").Text & "\" & tempstr & ".xlsx"
    Workbooks.Add
    Application.DisplayAlerts = False
    Application.AlertBeforeOverwriting = False
    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Filename:=fp
    Set dwb = Workbooks(tempstr) '*******Error occurs here*******

Answer 1

See: Windows().Activate works on every computer except one

This should fix the issue.

tempstr = "TSReports" & Month(gendate) & "_" & Day(gendate) & "_" & _
            Year(gendate) & Hour(gendate) & "h" & Minute(gendate) & "m" & _
            Second(gendate) & "s" & ".xlsx"

fp = gv.Range("b2").Text & "\" & tempstr 

Workbooks.Add
Application.DisplayAlerts = False
Application.AlertBeforeOverwriting = False
Application.DisplayAlerts = False
ActiveWorkbook.SaveAs Filename:=fp
Set dwb = Workbooks(tempstr) 

However this would be more robust:

Set dwb = Workbooks.Add
Application.DisplayAlerts = False
Application.AlertBeforeOverwriting = False
Application.DisplayAlerts = False
dwb.SaveAs Filename:=fp