删除范围内具有特定文本的单元格

Question

I have a range up that's 5k or so cells and I want to remove the cells that has specific texts on it. IE And, a, is, that, or, with, the, etc. Is there a way to this? Please help.

[A2].Select
Range("A2", Selection.End(xlDown)).Select

Dim crnge As Range
Dim wdelim
Dim rdelim

wdelim = Split("on,the,this,in,at,of,for,what,w,all,on,with", ",")

Set crnge = Selection

For Each rdelim In wdelim
    crnge.wdelim.Select
    .Delete (xlUp)
Next

I know this code doesn't work, this is just what I'm trying to do but I'm not sure how to do it.

Answer 1

Here I filter the data for each element in the array and delete all the entire row of visible cells.

Sub DeleteFilteredRows()
    Dim v
    With Application
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
    End With

    For Each v In Split("on,the,this,in,at,of,for,what,w,all,on,with", ",")
        With Range("A1").CurrentRegion
            On Error Resume Next
            'If you want all rows that have any of this phrases anywhere in
            'the cell use: Criteria1:="=*" & v & "*"                             

            .AutoFilter Field:=1, Criteria1:="=" & v , Operator:=xlAnd
            .Offset(1).SpecialCells(xlCellTypeVisible).EntireRow.Delete
            On Error GoTo 0
            .AutoFilter

        End With

    Next

    With Application
        .ScreenUpdating = True
        .Calculation = xlCalculationAutomatic
    End With
End Sub