Haskell+GTK 如何处理大量的小部件？

Question

I have a Glade file describing my interface. Its goal is to control a Nec monitor through local network. Therefore there are lots of widgets controlling how the monitor works:

I need to create the link between what I get/set from/to the monitor and the widgets. This means getting/setting values and attaching functions to widgets.

The Builder from GTK library requires to use IO () and cast every widget in order to call specific functions on them. This is kinda boring and add (unnecessary) lines of code.

module GUI where

import Graphics.UI.Gtk

data NecControlGUI = NecControlGUI
    { winNecControl :: Window
    , entIPAddress :: Entry
    , btnConnection :: Button
    , cbtVideoInput :: ComboBox
    , cbtPIPInput :: ComboBox
    , sclSharpness :: Scale
    , sclContrast :: Scale
    , sclBrightness :: Scale
    , sclBlackLevel :: Scale
    , sclColorTemperature :: Scale
    , cbtGamma :: ComboBox
    , sclBalance :: Scale
    , sclTreble :: Scale
    , sclBass :: Scale
    , sclVolume :: Scale
    , cbtLanguage :: ComboBox
    , sclMenuDisplayTime :: Scale
    }

loadGUI :: String -> IO NecControlGUI
loadGUI guiPath = do
    bdr <- builderNew

    builderAddFromFile bdr guiPath

    window <- builderGetObject bdr castToWindow "winNecControl"
    ipaddress <- builderGetObject bdr castToEntry "entIPAddress"
    connection <- builderGetObject bdr castToButton "btnConnection"
    videoinput <- builderGetObject bdr castToComboBox "cbtVideoInput"
    pipinput <- builderGetObject bdr castToComboBox "cbtPIPInput"
    sharpness <- builderGetObject bdr castToScale "sclSharpness"
    contrast <- builderGetObject bdr castToScale "sclContrast"
    brightness <- builderGetObject bdr castToScale "sclBrightness"
    blacklevel <- builderGetObject bdr castToScale "sclBlackLevel"
    colortemperature <- builderGetObject bdr castToScale "sclColorTemparature"
    gamma <- builderGetObject bdr castToComboBox "cbtGamma"
    balance <- builderGetObject bdr castToScale "sclBalance"
    treble <- builderGetObject bdr castToScale "sclTreble"
    bass <- builderGetObject bdr castToScale "sclBass"
    volume <- builderGetObject bdr castToScale "sclVolume"
    language <- builderGetObject bdr castToComboBox "cbtLanguage"
    menudisplaytime <- builderGetObject bdr castToScale "sclMenuDisplayTime"

    return NecControlGUI
        { winNecControl = window
        , entIPAddress = ipaddress
        , btnConnection = connection
        , cbtVideoInput = videoinput
        , cbtPIPInput = pipinput
        , sclSharpness = sharpness
        , sclContrast = contrast
        , sclBrightness = brightness
        , sclBlackLevel = blacklevel
        , sclColorTemperature = colortemperature
        , cbtGamma = gamma
        , sclBalance = balance
        , sclTreble = treble
        , sclBass = bass
        , sclVolume = volume
        , cbtLanguage = language
        , sclMenuDisplayTime = menudisplaytime
        }

Is there a way to automate this part?

I heard of LGtk, but is it the only way to do it?

Edit 2016-09-20 1

I tried to go the applicative way, but it doesn't seem that Haskell like combining applicative IO ? (but it's probably me)

module NecControlGUI where

import Graphics.UI.Gtk

data NecControlGUI = NecControlGUI
    { adjBalance :: Adjustment
    , winNecControl :: Window
    }

loadNecControlGUI :: String -> IO NecControlGUI
loadNecControlGUI guiPath = do
    bdr <- builderNew
    builderAddFromFile bdr guiPath
    let bget = builderGetObject bdr
    NecControlGUI <$> bget castToAdjustment "adjBalance"
                  <*> bget castToWindow "winNecControl"

Compiling outputs the following errors:

.../src/NecControlGUI.hs:16:23: error:
    • Couldn't match type ‘Adjustment’ with ‘Window’
      Expected type: IO Window
        Actual type: IO Adjustment
    • In the second argument of ‘(<*>)’, namely
        ‘bget castToWindow "winNecControl"’
      In a stmt of a 'do' block:
        NecControlGUI <$> bget castToAdjustment "adjBalance"
        <*> bget castToWindow "winNecControl"
      In the expression:
        do { bdr <- builderNew;
             builderAddFromFile bdr guiPath;
             let bget = builderGetObject bdr;
             NecControlGUI <$> bget castToAdjustment "adjBalance"
             <*> bget castToWindow "winNecControl" }

.../src/NecControlGUI.hs:16:28: error:
    • Couldn't match type ‘Window’ with ‘Adjustment’
      Expected type: GObject -> Adjustment
        Actual type: GObject -> Window
    • In the first argument of ‘bget’, namely ‘castToWindow’
      In the second argument of ‘(<*>)’, namely
        ‘bget castToWindow "winNecControl"’
      In a stmt of a 'do' block:
        NecControlGUI <$> bget castToAdjustment "adjBalance"
        <*> bget castToWindow "winNecControl"

Edit 2016-09-20 2

If I get rid of the let bdr = ... statement, everything works as expected.

Answer 1

It's not what you are looking for, but it is shorter. Use the Applicative instance to combine the calls to builderGetObject with the data constructor.

module GUI where

import Graphics.UI.Gtk

data NecControlGUI = NecControlGUI
    { ...
    }

loadGUI :: String -> IO NecControlGUI
loadGUI guiPath = do
    bdr <- builderNew

    builderAddFromFile bdr guiPath

    let bget = builderGetObject bdr

    NecControlGUI <$> bget castToWindow "winNecControl"
                  <*> bget castToEntry "entIPAddress"
                  <*> bget castToButton "btnConnection"
                  <*> bget castToComboBox "cbtVideoInput"
                  <*> bget castToComboBox "cbtPIPInput"
                  <*> bget castToScale "sclSharpness"
                  <*> bget castToScale "sclContrast"
                  <*> bget castToScale "sclBrightness"
                  <*> bget castToScale "sclBlackLevel"
                  <*> bget castToScale "sclColorTemparature"
                  <*> bget castToComboBox "cbtGamma"
                  <*> bget castToScale "sclBalance"
                  <*> bget castToScale "sclTreble"
                  <*> bget castToScale "sclBass"
                  <*> bget castToScale "sclVolume"
                  <*> bget castToComboBox "cbtLanguage"
                  <*> bget castToScale "sclMenuDisplayTime"