在Perl中引用和打印2D数组

Question

I've been reading about how you can't have an array of arrays in Perl thus I ended up struggling with references of arrays and I think I figure out how to return the array from a subroutine. However I can't get it to print the entire array after the return. Can someone explain to me why or how to debug this issue? It would be really appreciated indeed!

#!/usr/bin/perl
use strict;
use warnings;

#Subroutine to randomize the 2D Array:
sub randPattern {
my ($rand_ref) = @_;
my @RandBoard = @$rand_ref;

for (my $i = 0; $i <= $#RandBoard; $i++) {
  for (my $j = 0; $j <= $#RandBoard ; $j++) {
     $RandBoard[$i][$j] = 0 + int(rand(3 - 0));
     print "$RandBoard[$i][$j] ";
   }
   print "\n";
  }

return @RandBoard;
}

my @checkerArr =  (
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0]
);

my ($randomizedArr_ref) = randPattern(\@checkerArr); #sending arrayy as reference
my @randomizedArr = @$randomizedArr_ref; #dereferencing the returned array
print "___________________\n";

foreach (@randomizedArr){
print "$_ "; }
print "\n";

And the output is like this:

1 1 1 1 1 0 2 1 
1 0 0 0 2 2 0 1 
2 1 1 2 1 2 0 1 
1 2 0 2 0 1 0 1 
1 2 1 2 0 0 1 0 
2 1 0 1 0 0 0 2 
2 2 0 0 0 2 0 0 
1 1 1 0 0 1 1 1 
___________________
1 1 1 1 1 0 2 1 

As you can see it only outputs the first row of the array.

Answer 1

I think you've overcomplicated it somewhat.

Perl does do 2D arrays, and you're correct in thinking the the implementation of that is via references.

It may be useful to know that Data::Dumper is really handy for printing the contents of a complex data structure.

The core of your problem is in how these two iteract:

return @RandBoard;

this returns multiple values.

But this only 'uses' one of them, and discards the rest:

my ($randomizedArr_ref) = randPattern(\@checkerArr);

So what you're 'catching' is just the reference to the first line - and then printing it. If you were to try:

my ( @results ) = randPattern(\@checkerArr);

Then you'd come closer, but I'd suggest simple solution is:

return \@RandBoard;

Which returns the whole data structure as a reference:

foreach my $row ( @$randomizedArr_ref ) {
    print join " ", @$row; 
}

Making your code like this:

#!/usr/bin/env perl
use strict;
use warnings;


#Subroutine to randomize the 2D Array:
sub randPattern {
   my ($rand_ref) = @_;
   my @RandBoard = @$rand_ref;

   for ( my $i = 0; $i <= $#RandBoard; $i++ ) {
      for ( my $j = 0; $j <= $#RandBoard; $j++ ) {
         $RandBoard[$i][$j] = 0 + int( rand( 3 - 0 ) );
         print "$RandBoard[$i][$j] ";
      }
      print "\n";
   }

   return \@RandBoard;
}

my @checkerArr = (
   [ 0, 0, 0, 0, 0, 0, 0, 0 ],
   [ 0, 0, 0, 0, 0, 0, 0, 0 ],
   [ 0, 0, 0, 0, 0, 0, 0, 0 ],
   [ 0, 0, 0, 0, 0, 0, 0, 0 ],
   [ 0, 0, 0, 0, 0, 0, 0, 0 ],
   [ 0, 0, 0, 0, 0, 0, 0, 0 ],
   [ 0, 0, 0, 0, 0, 0, 0, 0 ],
   [ 0, 0, 0, 0, 0, 0, 0, 0 ]
);

my ($randomizedArr_ref) =
  randPattern( \@checkerArr );    #sending arrayy as reference


print "____\n";
foreach my $row (@$randomizedArr_ref) {
   print join " ", @$row, "\n";
}

But actually you could simplify your code massively:

foreach my $row ( @checkerArr ) { 
    $_ = int rand(3) for @$row; 
}

Or just:

my @checkerArr = map { 
                        [ 
                            map { int rand(3) } (1..8) #array of 8 random values
                        ] 
                     } (1..8); #8 rows. 

Answer 2

First, let me fix your code, then I'll explain...

#!/usr/bin/perl
use strict;
use warnings;

#Subroutine to randomize the 2D Array:
sub randPattern {
my ($rand_ref) = $_[0];
my @RandBoard = @$rand_ref;

for (my $i = 0; $i <= $#RandBoard; $i++) {
  for (my $j = 0; $j <= $#{$RandBoard[$i]} ; $j++) {
     $RandBoard[$i][$j] = 0 + int(rand(3 - 0));
     print "$RandBoard[$i][$j] ";
   }
   print "\n";
  }

return @RandBoard;
}

my @checkerArr =  (
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0],
  [0,0,0,0,0,0,0,0]
);

my ($randomizedArr_ref) = [randPattern(\@checkerArr)]; #sending arrayy as reference
my @randomizedArr = @$randomizedArr_ref; #dereferencing the returned array
print "___________________\n";

foreach (@randomizedArr){
    print(join(' ',@$_),"\n");
}

The main issue here is scalar context versus list context. You're returning a list from your subroutine and assigning that returned list in a scalar context ($randomizedArr_ref). You were getting an array reference (which was actually the last element of your outer array. You need to evaluate the return of the method in list context, so I added the square brackets around your method call ( [randPattern(\\@checkerArr)] ).

I also changed @_ to $_[0] to your setting of the parameter in the subroutine, which is a similar oversight. You were only getting the whlole parameter because you were passing in a single scalar (reference to an array).

Oh, and in your loop, I added a dereference of the array and joined with a space. I also moved the newline into the loop.

UPDATE: Found another error I overlooked. The size of the inner array tested in the inner for loop was using the size of the outer array (which happened to be the same). So I changed the inner for loop to get the size of the inner array with $#{$RandBoard[$i]} .