与ref传递的参数互操作

Question

I'm trying to call a C# function of an already existing library (and I don't have time to port the whole library to F#)

namespace ExportLib
{

    public static class Xlsx
    {
        public static bool TestSave(string proposed, ref string filename, ref string save_log) {

from an F# code

let getUserFile(proposed) : UserFile =
   let mutable filename = ""
   let mutable save_log = ""
   match Xlsx.TestSave(proposed, ref filename, ref save_log) with
   | true -> FileResult(filename)
   | false -> ErrorMsg(save_log)

meant to transform the function into algebraic data types with the objective to make illegal states unrepresentable .

type UserFile =
  // The value here is the file path.
| FileResult of string
  // The value here is the error msg.
| ErrorMsg of string

My issue is that the mutable F# filename remains unchanged despite it is assigned in the C# function (same problem with out string instead of ref string )

Answer 1

In F# ref is not a keyword but a function creating a reference cell. Xlsx.TestSave(proposed, ref filename, ref save_log) thus passes two newly created ref erence cells (pointing to mutable string values) into TestSave which in turn changes the ref cell to point to whatever string is assigned. Unfortunately, this is not observable from the outside, as there's nothing pointing to the ref cells. One approach is:

let getUserFile(proposed) : UserFile =
   let filename = ref ""
   let save_log = ref ""
   match Xlsx.TestSave(proposed, filename, save_log) with
   | true -> FileResult(!filename)
   | false -> ErrorMsg(!save_log)

As noted by @kvb you can also use

let getUserFile(proposed) : UserFile =
   let mutable filename = ""
   let mutable save_log = ""
   match Xlsx.TestSave(proposed, &filename, &save_log) with
   | true -> FileResult(filename)
   | false -> ErrorMsg(save_log)

and get rid of ref s altogether since F# 4.0 simplified the use of mutable s vs. ref .

Also, I try to avoid match ing on a simple bool , traditional if then else is shorter:

let getUserFile(proposed) : UserFile =
   let mutable filename = ""
   let mutable save_log = ""
   if Xlsx.TestSave(proposed, &filename, &save_log) then
       FileResult(filename)
   else
       ErrorMsg(save_log)

Obviously, using out instead of ref is even better, but for "... an already existing library ..." you might not have that choice.

Answer 2

If you use out instead of ref on the C# side, then you should be able to just do this instead:

let getUserFile(proposed) : UserFile =
    match Xlsx.TestSave proposed with
    | true, filename, _  -> FileResult(filename)
    | false, _, save_log -> ErrorMsg(save_log)

because trailing out parameters can be treated as a tuple with the actual result type.