非贪婪正则表达式仅匹配1个字符

Question

A have a list of files, some of whose names are suffixed with a .cloud. How do I write a regular expression that gets the filename without the .cloud part?

Here's a sample perl script I tried.

#! /usr/bin/perl -w

my @log_files = ('infolog.txt', 'errorlog.txt.cloud', 'dailyerrorlog.txt.cloud', 'trace.output.cloud', 'debug.log.cloud');

foreach my $file (@log_files)
{
    print $1."\n" if($file =~ /(.+?)(?:\.cloud)?/);
}

This prints the following:

$ perl test.pl 
i
e
d
t
d

If I get rid of the '?' that makes the .+ greedy, it matches everything, including .cloud.

#! /usr/bin/perl -w

my @log_files = ('infolog.txt', 'errorlog.txt.cloud', 'dailyerrorlog.txt.cloud', 'trace.output.cloud', 'debug.log.cloud');

foreach my $file (@log_files)
{
    print $1."\n" if($file =~ /(.+)(?:\.cloud)?/);
}

This prints the following:

$ perl test.pl 
infolog.txt
errorlog.txt.cloud
dailyerrorlog.txt.cloud
trace.output.cloud
debug.log.cloud

What I really want is a regular expression that'll print:

$ perl test.pl 
infolog.txt
errorlog.txt
dailyerrorlog.txt
trace.output
debug.log

I've modified my real use case to a very simple example here. I need to use regular expressions here to match the filename, so answers like

$file =~ s/\.cloud$//;
print $file."\n";

will not work for me.

I've tried a similar thing in C# too, with similar results.

    static void Main(string[] args)
    {
        Regex regex = new Regex(@"(?<filename>.+?)(?:\.cloud)?");
        string text = "abcdef.txt.cloud";
        Match match = regex.Match(text);
        if(match.Success)
        {
            Console.WriteLine("Found filename: {0}", match.Groups["filename"].Value);
        }
    }
    // Output
    // Found filename: a

Thanks for any help.

Answer 1

It's often easier to read/maintain regular expressions if you specify that the entire string must match. That's easy enough to do with ^ and $ , which match the start and end of the string.

Matching anywhere in the string: (.+?)(?:\\.cloud)?

Matching the entire string: ^(.+?)(?:\\.cloud)?$

In the second case, the non-greedy group will capture as little as possible, but will need to capture multiple characters to satisfy the match condition.

This doesn't cover every possible use case, but it tends to result in a regex that's easier to read six months from now.

Answer 2

It only matches one character because you told it to match the least possible number of characters, and .+ isn't allowed to match zero characters.

---

⇒ I'm going to use $PAT instead of .+ since you said it's a stand-in for something more complicated.

Despite your claims that s/// can't be used, it still seems to be the simplest solution to me.

my ($match) = map { s/\.cloud\z//r } $file =~ /^($PAT)\z/;  # 5.14+

or

my ($match) = map { ( my $s = $_ ) =~ s/\.cloud\z//; $s } $file =~ /^($PAT)\z/;

That said, it can also be achieved using a match:

my $match = $file =~ /^(?:($PAT)(?=\.cloud\z)|($PAT))/ ? ($1 // $2) : undef;

---

By the way, if $PAT was .+ , and I wanted to use a match, I'd use the following:

my ($match) = $file =~ /^((?:(?!\.cloud\z).)+)/s;

But it would be far simpler to use

my $match = $file =~ s/\.cloud\z//r;   # 5.14+

or

(my $match = $file) =~ s/\.cloud\z//;

Answer 3

The reason your pattern is matching only a single character is that the sub-pattern (?:\\.cloud)? is optional, so it can be satisfied by nothing at all. That leaves (.+?) free to match the shortest string allowable by the + quantifier, which is one character

It's easy to fix this by just anchoring the end of the pattern so that it has to match the whole of the string

This code works fine

use strict;
use warnings 'all';

my @log_files = qw/
    infolog.txt
    errorlog.txt.cloud
    dailyerrorlog.txt.cloud
    trace.output.cloud
    debug.log.cloud
/;

for ( @log_files ) {
    print "$1\n" if /(.+?)(?:\.cloud)?$/;
}

output

infolog.txt
errorlog.txt
dailyerrorlog.txt
trace.output
debug.log

Answer 4

Assign the file name to a temporary variable and modify it.

my @log_files = qw(
    infolog.txt
    errorlog.txt.cloud
    dailyerrorlog.txt.cloud
    trace.output.cloud
    debug.log.cloud
);

foreach my $file (@log_files)
{
    my $tmpry = $file;
    $tmpry =~ s/\.cloud$//;
    printf "%-25s %s\n", $file, $tmpry;
}