Excel数据透视表：无法按日期过滤

Question

I need to filter at number of data to show either containing one specific date or with the datefield left blank.

The macro below works with numbers and text (minor corrections naturally) but I cant make it work with date entries. Did not code the date value to avoid any language related issues.

Sub YesterdayBlank()
    ActiveSheet.PivotTables("PivotTable2").ClearAllFilters
    Dim yesterday As String
    yesterday = ActiveSheet.Range("F1").Value

With ActiveSheet.PivotTables("PivotTable2").PivotFields("OrderDate")
    For i = 1 To .PivotItems.Count
        If .PivotItems(i) = ("blank") Or .PivotItems(i) = yesterday Then
            .PivotItems(i).Visible = True
        Else
            .PivotItems(i).Visible = False
        End If
    Next i
End With
End Sub

The macro stops at: .PivotItems(i).Visible = False in the first round (i=1)

Any suggestions on this?

Answer 1

My apologies for the delay, and not helping with your issue. What if you try explicitly defining the PivotTable objects and working with their properties? This seems to work for me:

Sub YesterdayBlank()

    Dim yesterday As String
    Dim pt As PivotTable
    Dim pf As PivotField
    Dim pi As PivotItem

    yesterday = ActiveSheet.Range("F1").Value

    Set pt = ActiveSheet.PivotTables("PivotTable2")
    pt.ClearAllFilters

    Set pf = pt.PivotFields("OrderDate")

    For Each pi In pf.PivotItems
        If pi.Value = "(blank)" Or pi.Value = yesterday Then
            pi.Visible = True
        Else
            pi.Visible = False
        End If
    Next

    Set pf = Nothing
    Set pt = Nothing

End Sub

There is also a PivotFilters.Add2 method for the PivotField object. There are various FilterTypes you can add, though it isn't obvious to me that this will help you because you are looking to include blanks within your results. But I figured I'd share this as it may be useful for you in some other context:

pf.PivotFilters.Add2 XlPivotFilterType.xlSpecificDate, Value1:=yesterday

Here is some additional info about this method VBA Filter error