VBA中的工作日功能

Question

I'm trying to accomplish the below task in VBA using weekday function :

What I want to do is:

1. I have dates in col K and this code should run only on weekday dates and not on weekend dates.

2. I need to add additional text along with "Moved to SA (Compatibility Reduction)", let's say "Moved to SA (Failure)" . So, if col P has either "Moved to SA (Compatibility Reduction)" or "Moved to SA (Failure)" the coloring should happen.

3. This code should run only in sheet "Latency"

I have the below code but it's throwing an error message of :

wrong number of arguments or invalid property assignment

My code:

Sub Weekday()

Dim r, LastRow, RemainingDay As Double

 LastRow = Range("M:O").Cells(Rows.count, "A").End(xlUp).Row

 Application.ScreenUpdating = False

     For r = 2 To LastRow
       RemainingDay = 0

        If Weekday(Range("K" & r).Value, vbMonday) = 2 Then

              Select Case True
                     Case InStr(Range("P" & r).Text, "Moved to SA (Compatibility Reduction)") > 0, _
                    InStr(Range("P" & r).Text, "Moved to SA (Failure)") > 0

                 If Range("M" & r) - RemainingDay >= 1 Then
                     Range("M" & r).Cells.Font.ColorIndex = 3
                 Else
                      Range("M" & r).Cells.Font.ColorIndex = 0
                   End If

            End Select
         End If
    End If
Next r

End Sub

Answer 1

here's your Sub code refactored for what you asked

I also changed its previous name to WeekdayCheck() s not to hide VBA WeekDay() function

Sub WeekdayCheck()
    Dim r As Long, LastRow As Long
    Dim RemainingDay As Double '<--| you seem no to use it! if so get rid of it

    With Worksheets("Latency") '<--| reference worksheet "Latency"
        LastRow = .Cells(.Rows.Count, "A").End(xlUp).row '<--| get row index of its column A last not empty cell
        Application.ScreenUpdating = False
        For r = 2 To LastRow
            RemainingDay = 0 '<--| you seem no to use it! if so get rid of it

            If Weekday(.Range("K" & r).Value, vbSaturday) > 2 Then '<--| having 'Weekday()' function starting from "Saturday", it'll return numbers from 3 to 7 for not weekend weekdays
                Select Case True
                    Case InStr(.Range("P" & r).Text, "Moved to SA (Compatibility Reduction)") > 0, _
                         InStr(.Range("P" & r).Text, "Moved to SA (Failure)") > 0
                        If .Range("M" & r) - RemainingDay >= 1 Then
                            .Range("M" & r).Cells.Font.ColorIndex = 3
                        Else
                            .Range("M" & r).Cells.Font.ColorIndex = 0
                        End If
                End Select
            End If
        Next r
    End With
End Sub