Excel VBA：将公式值转换为文本

Question

I would like to have an answer to a following situation. I have basic VBA knowledge, sorry if I'm using incorrect expressions.

Let's say I would like to go on a long trip, but have to check the tires' conditions before departing. I have to have answers on 3 questions:

1. Are the tires under/overinflated? (answer to G1)
2. Is any of the tires flat? (G2)
3. Do I have to change the tires due to different weather conditions? (G3)

Thing is if any of the questions remain unanswered or the answer is Yes, further actions are required (in subsequent rows of the excel sheet, rows 5-9). In case all the 3 answers are No, tires are OK and I want the subsequent rows hidden.

To wrap up the conclusion, I have entered the following formula to G4:

=IF(AND(G1="No",G2="No",G3="No"), "No", "Yes") .

The formula answers perfectly. I pasted some excerpts of the code I have so far:

Worksheet_Change(ByVal Target As Range)
 Select Case Target.Address
  Case "$G$4"
  Rows("5:9").EntireRow.Hidden = (Target = "No")
...

The issue is that the code is not reading the answer of the formula in cell G4. If I delete the formula and rewrite the answer manually, the code is working perfectly and hides the subsequent rows. So the main issue is to convert the result of the formula in G4 to make it readable for the code.

Can anybody help please? Or is there a better solution? Thanks in advance.

Answer 1

The problem is not "to convert the result of the formula in G4 to make it readable for the code" since it is readable. But the target of Worksheet_Change event will not be G4 but either G1 or G2 or G3 which will then change the value of G4 through the formula calculation. But this calculation is not a Worksheet_Change event but a Worksheet_Calculate event.

So either you are checking whether G1 or G2 or G3 is target in Worksheet_Change event

Private Sub Worksheet_Change(ByVal Target As Range)
 Select Case Target.Address
  Case "$G$1", "$G$2", "$G$3"
  Me.Rows("5:9").EntireRow.Hidden = (Me.Range("G4").Value = "No")
 End Select
End Sub

Or you check the result of the formulas recalculation in Worksheet_Calculate event:

Private Sub Worksheet_Calculate()
 Me.Rows("5:9").EntireRow.Hidden = (Me.Range("G4").Value = "No")
End Sub