我需要找到最大值和最小值 Rowwise

Question

operator1,4578
operator2,1234
operator3,9875
operator4,6357
operator1,6353
operator4,9765
operator1,6347
operator1,6798
operator3,6793
operator3,1465
operator4,6796
operator4,3333

I need to find out minimum and maximum value of each operator using awk and python (need command in awk as well in Python too) and output will be as below :

Name        Min     Max
operator1   4578    6798 
operator2   1234    
operator3   1465    9875 
operator4   3333    9765 

Can anyone help me out please

Answer 1

@amit kumar: Try:

awk -F, 'FNR==NR{A[$1]=A[$1]>$NF?A[$1]:$NF;B[$1]=B[$1]>$NF?$NF:(B[$1]?B[$1]:$NF);next} FNR==1 && FNR!=NR{print "Name Min Max"}($1 in A){print $1 "\t" B[$1] "\t" A[$1];delete B[$1];delete A[$1]}'  Input_file  Input_file

Here I am making field separator as a "," then FNR==NR condition will make sure that it gets executed only when first time Input_file is being read. where FNR and NR both are awk's in-built keywords and define the line numbers in it. FNR's value will be RESET whenever a new Input_file being read where N's value will be keep on increasing till all the files being read successfully. Then in that block I am creating an array named A whose index is $1 and where I am checking if previous A[$1]'s value is greater than current same index of array compare to $NF then change A[$1]'s value to current $NF as keep it as it is(this is basically for having maximum values for each $1 of line), same thing I am doing to get the MINIMUM values for $1 in Input_file and storing values into array B. next will be skipping all the next coming statements so only FNR==NR condition will be executed. Now FNR==1 && FNR!=NR condition will be only TRUE when second file's 1st line is being read because before writing actual output I need to write the heading columns. ($1 in A) now checking if current line's $1 is present in array A then print the current $1 and array A's value and then array B's value as per OP's request.

EDIT: Adding a non-one liner form of solution too now.

awk -F, 'FNR==NR{
                 A[$1]=A[$1]>$NF?A[$1]:$NF;
                 B[$1]=B[$1]>$NF?$NF:(B[$1]?B[$1]:$NF);
                 next
                }
         FNR==1 && FNR!=NR{
                                print "Name Min Max"
                          }
         ($1 in A){
                        print $1 "\t" B[$1] "\t" A[$1];
                        delete B[$1];
                        delete A[$1]
                  }
        '    Input_file  Input_file

Answer 2

You can try this:

awk -F, '
   min[$1]>$2||!min[$1]{
      min[$1]=$2
   } 
   max[$1]<$2{
      max[$1]=$2
   } 
   END{
     for(i in max){
        print i,min[i],(max[i]!=min[i]?max[i]:"")
     }
   }' file

This script make used of 2 array min and max which are filled with values while parsing the input file.

When parsing is finished, both array are printed.

Note that max[i]!=min[i]?max[i]:"" is skipping the max value in case this is the same as the min one.

I let you put the header line, and play with column command in case you want indentation...