我需要找到最大值和最小值 Rowwise

Question

operator1,4578
operator2,1234
operator3,9875
operator4,6357
operator1,6353
operator4,9765
operator1,6347
operator1,6798
operator3,6793
operator3,1465
operator4,6796
operator4,3333

我需要使用awk和python找出每个运算符的最小值和最大值（也需要awk命令以及Python命令），输出如下：

Name        Min     Max
operator1   4578    6798 
operator2   1234    
operator3   1465    9875 
operator4   3333    9765 

谁能帮我一下

Answer 1

@amit kumar：尝试：

awk -F, 'FNR==NR{A[$1]=A[$1]>$NF?A[$1]:$NF;B[$1]=B[$1]>$NF?$NF:(B[$1]?B[$1]:$NF);next} FNR==1 && FNR!=NR{print "Name Min Max"}($1 in A){print $1 "\t" B[$1] "\t" A[$1];delete B[$1];delete A[$1]}'  Input_file  Input_file

在这里，我将字段分隔符设为“,”，然后 FNR==NR 条件将确保它仅在第一次读取 Input_file 时执行。 其中 FNR 和 NR 都是 awk 的内置关键字并定义其中的行号。 每当读取新的 Input_file 时，FNR 的值将被重置，其中 N 的值将继续增加，直到成功读取所有文件。 然后在那个块中，我创建了一个名为 A 的数组，其索引为 $1，并在其中检查前一个 A[$1] 的值是否大于当前相同的数组索引与 $NF 相比，然后更改 A[$1] 的值到当前 $NF 保持原样（这基本上是为了让每行 $1 具有最大值），我正在做的事情是在 Input_file 中获取 $1 的最小值并将值存储到数组 B 中。接下来将跳过所有接下来的语句，因此只会执行 FNR==NR 条件。 现在 FNR==1 && FNR!=NR 条件将仅在读取第二个文件的第一行时为 TRUE，因为在写入实际输出之前我需要写入标题列。 （A 中的 $1）现在检查当前行的 $1 是否存在于数组 A 中，然后根据 OP 的请求打印当前 $1 和数组 A 的值，然后打印数组 B 的值。

编辑：现在也添加一种非单衬形式的解决方案。

awk -F, 'FNR==NR{
                 A[$1]=A[$1]>$NF?A[$1]:$NF;
                 B[$1]=B[$1]>$NF?$NF:(B[$1]?B[$1]:$NF);
                 next
                }
         FNR==1 && FNR!=NR{
                                print "Name Min Max"
                          }
         ($1 in A){
                        print $1 "\t" B[$1] "\t" A[$1];
                        delete B[$1];
                        delete A[$1]
                  }
        '    Input_file  Input_file

Answer 2

你可以试试这个：

awk -F, '
   min[$1]>$2||!min[$1]{
      min[$1]=$2
   } 
   max[$1]<$2{
      max[$1]=$2
   } 
   END{
     for(i in max){
        print i,min[i],(max[i]!=min[i]?max[i]:"")
     }
   }' file

该脚本使用了 2 个数组min和max ，它们在解析输入文件时填充了值。

解析完成后，打印两个数组。

请注意， max[i]!=min[i]?max[i]:""正在跳过最大值，以防它与最小值相同。

我让你放置标题行，并在你想要缩进的情况下使用column命令......