VBA Vlookup将值从sheet1填充到sheet2

Question

Someone can tell me please why is my Func doesn't write to cells nothing? There is no error just nothing happening.

Sub VL_Depositors()

On Error Resume Next

Dim Dept_Row As Long
Dim Dept_Clm As Long
Dim Table1, Table2 As Range

Worksheets("Search term report (1)").Select
Set Table1 = Range("I2:I10")

Worksheets("MySheet").Select
Set Table2 = Range("E2:F39")

Worksheets("Search term report (1)").Select
Dept_Row = Sheet1.Range("F2").row
Dept_Clm = Sheet1.Range("F2").Column

For Each cl In Table1
    Cells(Dept_Row, Dept_Clm) = Application.WorksheetFunction.VLookup(cl,Table2, 2, False)
    Dept_Row = Dept_Row + 1
Next cl

End Sub

Answer 1

If I understood what you are trying to achieve in your code is to loop through cells in Table1 Range (from "Search term report (1)" sheet), and to see if it's found in Table2 Range (from "MySheet" sheet).

If it's found, then put the value in Column F in "Search term report (1)" sheet, for that I am using the Cl.Offset(, -3) .

Also, there is a need to handle errors in case Application.VLookup doesn't find a value.

Code

Option Explicit

Sub VL_Depositors()

Dim Dept_Row As Long
Dim Dept_Clm As Long
Dim Table1 As Range, Table2 As Range
Dim Cl As Range

Set Table1 = Worksheets("Search term report (1)").Range("I2:I10")
Set Table2 = Worksheets("MySheet").Range("E2:F39")

For Each Cl In Table1.Cells
    If Not IsError(Application.VLookup(Cl.Value, Table2, 2, False)) Then ' <-- VLookup was successful
        ' use offset -3 columns  >> 3 columns to the left of column "I" is column "F"
        Cl.Offset(, -3).Value = Application.VLookup(Cl.Value, Table2, 2, False)
    Else
        Cl.Offset(, -3).Value = "Value not Found!"
    End If
Next Cl

End Sub