Windows构建和操作“Goto此时出乎意料”

Question

Hoping for some assistance explaining and verifing this script I am getting an error "goto was unexpected at this time"

I attempting to created a script that gets the windows version number... depending on the version number if its higher or equals then x it has to goto action 1 (FTRDWIN8) and when the version number is less then x it has to goto action 2

@echo off

::parsing the output of "ver" to getting windows version number 
::excuting. 

set strbuild=6.2

for /f "tokens=4-5 delims=. " %%i in ('ver') do set VERSION=%%i.%%j 
if "%version%" geq "%strbuild%" goto FTRDWIN8
if "%version%" lss "%strbuild%" goto FTRDWINXPVI7


:FTRDWIN8
"C:\Windows\write.exe"
exit

:FTRDWINXPVI7
"C:\Windows\notepad.exe"
exit

Answer 1

If only compares strings or integers; any non numeric char forces string comparison on a char by char base and then 10.0 is less than 8.1

This slightly changed batch

@echo on
set strbuild=6.2

for /f "tokens=4-5 delims=. " %%i in ('ver') do set VERSION=%%i.%%j 
if "%version%" geq "%strbuild%" goto FTRDWIN8
if "%version%" lss "%strbuild%" goto FTRDWINXPVI7

Goto :eof
:FTRDWIN8
"C:\Windows\write.exe"
Exit

:FTRDWINXPVI7
"C:\Windows\notepad.exe"
Exit

has this transcript with echo on:

set strbuild=6.2
for /F "tokens=4-5 delims=. " %i in ('ver') do set VERSION=%i.%j
set VERSION=10.0
if "10.0 " GEQ "6.2" goto FTRDWIN8
if "10.0 " LSS "6.2" goto FTRDWINXPVI7
"C:\Windows\notepad.exe"
Goto :Eof

Answer 2

I copied your code and executed, and I cannot reproduce your error, though it gives the wrong result. I have windows 10 (version 10.0.14393), and your IF statement does a string comparison, so "10.0" is less than "6.2"

I cannot see how your code could ever give an error message of "goto was unexpected at this time" . If you modify your code to enable delayed expansion and use !var! instead of %var% , then your code could not possibly give that error.

You should remove the ECHO OFF so you can see where the error message is coming from. I suspect it is in some other unrelated code, but can't be sure.

As I stated earlier, (and also pointed out by LotPings) your logic is wrong because your IF statement with quotes and decimal point does a string comparison, not a numeric comparison.

Here is corrected logic that does the comparison in multiple steps - each version node must be tested independently. I don't see any reason to set any environment variable. Also, I like to use EXIT /B instead of EXIT . I suspect that the code may be locale dependent - I'm not sure if the VER command changes its output format depending on the locale.

@echo off
for /f "tokens=4-5 delims=. " %%A in ('ver') do (
  if %%A gtr 6 goto FTRDWIN8
  if %%A equ 6 if %%B geq 2 goto FTRDWIN8
)

:FTRDWINXPVI7
"C:\Windows\notepad.exe"
exit /b

:FTRDWIN8
"C:\Windows\write.exe"
exit /b