通过vb.net更新SQL Server数据库中的记录

Question

Hey Guy I need your help

Im struggling on how to update any record in database sql server from vb.net

First. I made a class in vb to put all the functions and to all them from the button UPDATE event ie to be more organised.

I've managed to do all the coding for it (the update feature) perfectly, with no errors, but surprisingly, it does not update any field.

PLEASE HELP

Here is my class where I make all the functions and call them from the button evens:

 Public Function UpdateDataRecord(Command As String) As Integer
    Try
        SQLConnector.Open()
        SQLCommand = New SqlCommand(Command, SQLConnector)


        Dim ChangeCount As Integer = SQLCommand.ExecuteNonQuery()

        SQLConnector.Close()

        Return ChangeCount
    Catch ex As Exception
        MsgBox(ex.Message)
    End Try

    Return 0
End Function

Here my update button even

 Private Sub updateBtn_Click(sender As Object, e As EventArgs) Handles updateBtn.Click

    If IDTextBox.Text <> "" Then
        If (NameTextBox.Text.Length) >= 3 Then

            Dim UpdateThisNow As String = "Update tblActivity " &
                           "Set Name='" & NameTextBox.Text & "' " &
                         "WHERE ID ='" & IDTextBox.Text & "' "


            If sqlcontrol.UpdateDataRecord(UpdateThisNow) = 0 Then

                MsgBox("Not Found")

            Else
                MsgBox("Successfully updated")

            End If

        Else
            MsgBox("Data Entered too short!")
        End If

    Else
        MsgBox("You must provide ID number")

    End If




End Sub

Answer 1

Try to replace your function with this.

Public Function UpdateDataRecord(ByVal name As String, ByVal id As Integer) As Integer
    Dim result As Integer 'will save the affected records count later
    Dim sqlConnStr As String = "ConnectionString" 'put a valid connection string value here
    Dim sqlCmdStr As String = "UPDATE tblActivity SET Name = @Name WHERE ID = @ID" 'your SQL UPDATE query with parameters to avoid SQL injection attacks
    Using sqlConn As New SqlConnection(sqlConnStr) 'declare a SQL connection object and uses your connection string
        Using sqlCmd As New SqlCommand(sqlCmdStr) With {.Connection = sqlConn} 'declare a SQL command object and uses your UPDATE query, and the connection object above
            Try
                sqlConn.Open() 'Open the connection
                With sqlCmd.Parameters
                    .Clear() 'clear the parameters
                    .AddWithValue("Name", name) 'add the value to the parameterized query using the values you got from your textbox
                    .AddWithValue("ID", id)
                End With
                result = sqlCmd.ExecuteNonQuery() 'set the value of the result integer
            Catch ex As Exception
                result = 0
            Finally
                sqlConn.Close()
            End Try
        End Using
    End Using
    Return result
End Function

Then call it like this:

sqlcontrol.UpdateDataRecord(NameTextBox.Text, IDTextBox.Text)