将此较长的Excel日期公式转换为VBA

Question

I have this Excel formula below;

DATE(LEFT(A1,3),MID(A1,6,1),MID(A1,7,1))

I would like to convert this Excel formula into a VBA user-defined function.

Public Function getDate(input_date As String)
    'code to convert DATE(LEFT(A1,3),MID(A1,6,1),MID(A1,7,1)) to VBA
End Function

This is tricky because there are functions used inside function parameters. Like LEFT used inside DATE.

EDIT: If possible, I would like to use the Excel formula directly inside the VBA function with minimal modification. Is it possible to do this in Excel VBA?

Answer 1

It's not really any different to what you are doing in Excel, at least as far as calling functions within functions:

Public Function getDate(input_date As String) As Date
    getDate = DateSerial(1900 + CInt(Left(input_date, 3)), _
                         CInt(Mid(input_date, 6, 1)), _
                         Cint(Mid(input_date, 7, 1)))
End Function

The CInt calls aren't strictly necessary, VBA will coerce the expressions returned from Left and Mid to numeric values, just as Excel does - but I like to explicitly show the conversions in these sort of statements. But if you don't want them, you could use the following, which is basically identical to the Excel formula except for DateSerial instead of DATE . (The VBA Date function just returns today's date.)

Public Function getDate(input_date As String) As Date
    getDate = DateSerial(1900 + Left(input_date, 3), Mid(input_date, 6, 1), Mid(input_date, 7, 1))
End Function

The addition of 1900 to the year is required because Excel handles that differently to VBA. Excel treats a year of 20 as 1920, and a year of 104 as 2004. VBA uses a windowing approach where years less than 30 are treated as 20yy, and years between 30 and 99 are treated as 19yy, and years greater than or equal to 100 are treated as 0yyy.

---

And, although I would STRONGLY discourage its use, you could use the exact same EXCEL formula within VBA using Evaluate :

Public Function getDate(input_date As String) As Variant
    getDate = Evaluate("DATE(LEFT(""" & input_date & """,3),MID(""" & input_date & """,6,1),MID(""" & input_date & """,7,1))")
End Function

Answer 2

You can try something like this...

Public Function getDate(input_date As String)
    getDate = CDate(Evaluate("DATE(LEFT(" & input_date & ",4),MID(" & input_date & ",5,2),MID(" & input_date & ",7,2))"))
End Function

Sub Test()
MsgBox getDate("20170521")
End Sub