这个奇怪的单子绑定如何工作？

Question

This is probably a very noob question but I was playing around with the bind operator in Haskell and I encountered a way to repeat a string using it.

[1..3] >>= const "Hey"
-- Yields "HeyHeyHey"
[1..3] >>= return "Hey"
-- Also yields the same result

I understand how >>= (\\_ -> return "Hey") would yield ["Hey", "Hey", "Hey"] but I don't understand why (\\_ -> "Hey") repeats the string or why >>= return "Hey" does the same thing.

Answer 1

I understand how >>= (\\_ -> return "Hey") would yield ["Hey", "Hey", "Hey"]

right. return "Hey" is in this case the same as ["Hey"] , because

instance Monad [] where
  return x = [x]

So

([1..3] >>= \_ -> return "Hey")
  ≡  ([1..3] >>= \_ -> ["Hey"])
  ≡  ["Hey"] ++ ["Hey"] ++ ["Hey"]
  ≡  ["Hey", "Hey", "Hey"]

Now, >>= (\\_ -> "Hey") can also be be written with a list-result in the lambda, because strings are just lists of characters.

([1..3] >>= \_ -> "Hey")
  ≡  ([1..3] >>= \_ -> ['H','e','y'])
  ≡  ['H','e','y'] ++ ['H','e','y'] ++ ['H','e','y']
  ≡  ['H','e','y','H','e','y','H','e','y']
  ≡  "HeyHeyHey"

As for >>= return "Hey" , that's a different beast. The return belongs to a completely different monad here, namely the function functor .

instance Monad (x->) where
  return y = const y

Hence it's kind of clear that ([1..3] >>= const "Hey") and ([1..3] >>= return "Hey") give the same result: in that example, return is just another name for const !

Answer 2

The return being used here is not for the list monad, but for the function monad, in which this definition holds:

return x = \_ -> x

So this is the same as:

[1,2,3] >>= (\_ -> "Hey")

and since (>>=) is the same as concatMap for lists, we have:

concatMap (\_ -> "Hey") [1,2,3]

Can you see why this yields "HeyHeyHey" ?