Emacs-如何更改杀死以删除？

Question

I only want Cw and Mw to modify the kill-ring, along with the system's clipboard [ Cc (copy), Cx (cut)].

I use Md and M-DEL often, but I do not want to yank and then cycle through My every time.

I was looking at the emacs manual but it does not answer my question.

Example: I want to bind Md "kill-word" to "delete-word", but "delete-word" does not exist. How do I make it so? Any help would be appreciated.

Answer 1

I think you want to use delete-region instead of kill-region so the text isn't saved in the kill-ring, eg. something along the lines of

(defun my-delete-word (start)
  (interactive "d")
  (backward-word)
  (delete-region (point) start))

Answer 2

From EmacsWiki https://www.emacswiki.org/emacs/BackwardDeleteWord

(defun delete-word (arg)
  "Delete characters forward until encountering the end of a word.
With argument, do this that many times."
  (interactive "p")
  (if (use-region-p)
      (delete-region (region-beginning) (region-end))
    (delete-region (point) (progn (forward-word arg) (point)))))

(defun backward-delete-word (arg)
  "Delete characters backward until encountering the end of a word.
With argument, do this that many times."
  (interactive "p")
  (delete-word (- arg)))

(global-set-key (read-kbd-macro "<M-DEL>") 'backward-delete-word)

Answer 3

I made a macro to change any kill command into a delete command.

(defmacro delete-instead-of-kill (&rest body)
  "Replaces `kill-region' with `delete-region' in BODY."
  `(cl-letf (((symbol-function 'kill-region)
              (lambda (beg end &optional region)
                ;; FIXME: account for region arg
                (delete-region beg end))))
     ,@body))

(defun delete-word (&optional arg)
  "Like `kill-word', but deletes instead of killing."
  (interactive "p")
  (delete-instead-of-kill (kill-word arg)))

I use a similar macro for copying.

(defmacro copy-instead-of-kill (&rest body)
  "Replaces `kill-region' with `kill-ring-save' in BODY."
  `(cl-letf (((symbol-function 'kill-region)
              (lambda (beg end &optional region)
                (kill-ring-save beg end region)
                (setq this-command 'kill-region))))
     ,@body))