以Ada标记类型创建2D数组字段

Question

I'm trying to create a Java/C class equivalent in Ada. From what I've researched -- the equivalent would be a Tagged Record. I'm wanting to create a field that is a 2D Array, however with the code below -- it gives me the following errors.

Code:

package Foo is
type Bar is tagged
    record
        field1 : Integer;
        field2 : Integer;
        type field3 is array (1 .. 10, 1 .. 5) of Integer;
    end record;
end Foo;

Error:

foo.ads:6:25: missing "end record;" for "record" at line 8

foo.ads:7:17: no "record" for this "end record"

This tells me that "Anonymous arrays are not allowed as components".

package Foo is
type Bar is tagged
    record
        field1 : Integer;
        field2 : Integer;
        field3 : array (1 .. 10, 1 .. 5) of Integer;
    end record;
end Foo;

Answer 1

The reason your second version fails is that

field3 : array (1 .. 10, 1 .. 5) of Integer;

declares a new, unnamed (anonymous), type ( array (1 .. 10, 1 .. 5) of Integer ), and you're not allowed to nest type declarations.

Depending on your application, you might try

type Twod_Array is array (Integer range <>, Integer range <>) of Integer;
type Bar is tagged
   record
      field1 : Integer;
      field2 : Integer;
      field3 : Twod_Array (1 .. 10, 1 .. 5);
   end record;

or

type Twod_Array is array (Positive range <>, Positive range <>) of Integer;
type Bar (First, Second : Natural) is tagged
   record
      field1 : Integer;
      field2 : Integer;
      field3 : Twod_Array (1 .. First, 1 .. Second);
   end record;

[Hmm. I said First, Second : Natural to allow for zero-length arrays. But I'm not sure what the point of A_Bar : Bar (0, 10); would be!]

Answer 2

You attempt to declare one named type inside the declaration of another named type. You can't do that.

Also, Ada does not allow record fields of anonymous types, so you have to ensure that you have declared all the types you need for the fields of your record, before the declaration of the record itself.

Are you sure you need values in the range -32_768 .. 32_767 (that's all Ada promises about the type Integer )? Normally one would declare a type matching the requirements of the problem. (Of course, if the problem is to match the C type int closely, then one should use Interfaces.C.int .)