Excel VBA清除一个单元格中的内容（如果另一个为空）

Question

Below code is used to add information in specified cells if there is value in Column A, same row. Everything works except I want to clear the value in Column E for the same row if I delete the value in column A.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Me.Range("A:A")) Is Nothing Then Exit Sub
    Application.EnableEvents = False             'to prevent endless loop
    On Error GoTo Finalize                       'to re-enable the events

    For Each columnAcell In Target.Cells
        columnAcell.Offset(0, 3) = Mid(columnAcell, 2, 3)
    Next

    Dim w1 As Worksheet, w2 As Worksheet
    Dim c As Range, FR As Variant

    Application.ScreenUpdating = False

    Set w1 = Workbooks("Excel VBA Test.xlsm").Worksheets("AP_Input")
    Set w2 = Workbooks("Excel VBA Test.xlsm").Worksheets("Datakom")

    For Each c In w1.Range("D2", w1.Range("D" & Rows.Count).End(xlUp))
        FR = Application.Match(c, w2.Columns("A"), 0)
        If IsNumeric(FR) Then c.Offset(, 1).Value = w2.Range("B" & FR).Value
    Next c

    Finalize:
    Application.EnableEvents = True
End Sub

Answer 1

Assuming the "columnAcell" is to represent a range of cells in the column A, how about redoing the first loop as follows?

For Each columnAcell In Target.Cells
    columnAcell.Offset(0, 3) = Mid(columnAcell, 2, 3)
    If ISEMPTY(columnAcell.value) Then columnAcell.Offset(0, 4).ClearContents
Next

Answer 2

You may add an IF condition within the For Loop to check if a cell in column A is empty like this...

For Each columnAcell In Target.Cells
    If columnAcell <> "" Then
        columnAcell.Offset(0, 3) = Mid(columnAcell, 2, 3)
    Else    'if column A cell is empty
        columnAcell.Offset(0, 4) = ""   'Clear the cell content in column E on same row
    End If
Next