Excel VBA - 清除最后使用的单元格的内容

Question

Worksheets("happy").Unprotect
Range("C4").Select
Range(Selection, Selection.End(xlToRight)).Select
Range(Selection, Selection.End(xlDown)).Select
Range("C4:BB100").Select
Range(Selection, Selection.End(xlDown)).Select
Selection.ClearContents

I want to clear the range from C4 to the last used cell which constantly changes. Does anyone have any idea?

Answer 1

This is my attempt.

Sub del_range()
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("happy")
'ws.Range(Cells(4, 3), Cells(ws.UsedRange.SpecialCells(xlCellTypeLastCell).Row, ws.UsedRange.SpecialCells(xlCellTypeLastCell).Column)).Select
ws.Range(Cells(4, 3), Cells(ws.UsedRange.SpecialCells(xlCellTypeLastCell).Row, ws.UsedRange.SpecialCells(xlCellTypeLastCell).Column)).ClearContents
End Sub

The commented line would just select it, but i recommend not doing that because select needs time. It looks in which line the last value in this sheet is and in which column is the last value and deletes all from cell C4 to last row and cell.

Answer 2

The Range from a Cell to the Last Cell

Option Explicit

Sub clearHappy()
    With ThisWorkbook.Worksheets("happy")
        '.Unprotect
        With .Range("C4")
            Dim rg As Range:
            Set rg = .Resize(.Worksheet.Rows.Count - .Row + 1, _
                .Worksheet.Columns.Count - .Column + 1)
            'Debug.Print rg.Address
            Dim cel As Range
            Set cel = rg.Find("*", , xlFormulas, , xlByRows, xlPrevious)
            If Not cel Is Nothing Then
                'Debug.Print cel.Address
                Set rg = rg.Resize(cel.Row - .Row + 1, _
                    rg.Find("*", , , , xlByColumns, xlPrevious).Column _
                    - .Column + 1)
                'Debug.Print rg.Address
                rg.ClearContents
            End If
        End With
        '.Protect
    End With
End Sub