如何在批处理脚本中串联两个文件路径而不会出现尾随的'\\'歧义？

Question

For the below code I get LIBDIR from a props file.

set strDestPath=%LIBDIR%"\Libraries\python\win\"
set strPythonZipSourcePath=%CTEDIR%"\Libraries\python\win\Python27.zip"

Call :UnZipFile %strDestPath% %strPythonZipSourcePath%

If the props file has the LIBDIR as say 'D:\\WinLibraryes\\', then I end up getting my strDestPath as

D:\WinLibraryes\\Libraries\python\win\
/*With double slash in the path*/

Then the UnZipFile fails trying to access the location.

The props file may have the LIBDIR with or without trailing '\\'.

How can I concatenate these paths to get a proper path like the below one?

D:\WinLibraryes\Libraries\python\win\

Answer 1

I will mimic your LIBDIR as TMPLIBDIR to demonstrate. We test the last character of TMPLIBDIR to see if it is a \\ or not.. Instead of removing anything from TMPLIBDIR, we rather decide whether we place the first \\ there afterwards. To see different result, Add \\ after Path in the script.

@echo off
setlocal enabledelayedexpansion
set "TMPLIBDIR=D:\WinLibraryes"
    if not "!TMPLIBDIR:~-1!"=="\" (
        set "strDestPath=%TMPLIBDIR%\Libraries\python\win\"
        ) else (
        set "strDestPath=%TMPLIBDIR%Libraries\python\win\"
 )

First condition adds a \\ after TMPLIBDIR and else condition does not.

Answer 2

I suppose that you could Set the new variables whilst checking if those from the props file exist. (after all if they don't exist the script may as well not run)

SetLocal EnableExtensions
PushD "%CD%"
CD /D "%LIBDIR%" 2>Nul || Exit /B
If Not Exist "%CD%\Libraries\python\win\" Exit /B
Set "strDestPath=%CD%\Libraries\python\win"
CD /D "%CTEDIR%" 2>Nul || Exit /B
If Not Exist "%CD%\Libraries\python\win\Python27.zip" Exit /B
Set "strPythonZipSourcePath=%CD%\Libraries\python\win\Python27.zip"
PopD

Call :UnZipFile "%strDestPath%" "%strPythonZipSourcePath%"

Answer 3

I use a handy subroutine to build paths:

@setlocal ENABLEEXTENSIONS
@set prompt=$G

set _var1=\Dir1\\\\Dir2\
set _var2=\Dir3\Dir4
set _var3=Relative\\\\Path
set _var4="QuotedPath\\\\Path%"

call :SetFQDP _var5 %_var1%\%_var2%
set _var5

call :SetFQDP _var5 %_var3%
set _var5

call :SetFQDP _var5 %_var4%
set _var5

@exit /b 0

@rem Set specified variable to a fully qualified drive\path name with no
@rem redundant backslashes. Convert all forward slashes to backslashes.
@rem Removes quotes.
:SetFQDP
@set %1=%~f2
@exit /b %_ERROR_SUCCESS_%

Produces:

> test

>set _var1=\Dir1\\\\Dir2\

>set _var2=\Dir3\Dir4

>set _var3=Relative\\\\Path

>set _var4="QuotedPath\\\\Path"

>call :SetFQDP _var5 \Dir1\\\\Dir2\\\Dir3\Dir4

>set _var5
_var5=D:\Dir1\Dir2\Dir3\Dir4

>call :SetFQDP _var5 Relative\\\\Path

>set _var5
_var5=D:\TMP\Joseph\Relative\Path

>call :SetFQDP _var5 "QuotedPath\\\\Path"

>set _var5
_var5=D:\TMP\Joseph\QuotedPath\Path

Note that if the drive letter is not supplied the current drive is used. If a final trailing slash is passed in, it will be preserved. The fully qualified path of the current directory is always prefixed to any relative path (doesn't start with '/' or '\\'). The resulting path does not have to exist, so you'll either have to create it or test for its existence.

Pulling it all together for you:

@call :SetFQDP strDestPath=%LIBDIR%"\Libraries\python\win\"
@call :SetFQDP strPythonZipSourcePath=%CTEDIR%"\Libraries\python\win\Python27.zip

Call :UnZipFile %strDestPath% %strPythonZipSourcePath%
exit /b

@rem Set specified variable to a fully qualified drive\path name with no
@rem redundant backslashes. Convert all forward slashes to backslashes.
@rem Removes quotes.
:SetFQDP
@set %1=%~f2
@exit /b %_ERROR_SUCCESS_%