什么食谱与苹果烤饼最相似-按照与该食谱相似的顺序输出其他食谱的成分列表

Question

Here is what I have done so far:

MATCH (:Cake{name: 'Apple Scones'})-[n]-(a)
WITH COLLECT(a) AS list
MATCH (b)-[:CONTAINS]->(a)
RETURN list

I am trying to get the cake that is most similar to the ingredients in apple scones. I have the list of all ingredients in apple scones, but am not sure how to compare it with the rest of the cakes.

Any feedback will be greatly appreciated.

Thanks

Answer 1

This query may do what you want:

MATCH (:Cake {name: 'Apple Scones'})-[:CONTAINS]->(i)<-[:CONTAINS]-(recipe)
RETURN recipe, COLLECT(i) AS sharedIngredients
ORDER BY SIZE(sharedIngredients) DESC;

It returns each recipe that has at least one ingredient in common with Apple Scones , along with a list of shared ingredients. The results are returned in descending order by the number of shared ingredients.

Answer 2

That query won't work so well...in the WITH you didn't bring over a , so your subsequent match will match on all nodes that have a :CONTAINS relationship to anything. That's going to be a ton of nodes.

You might look at this knowledge base article for insight.

Here's one query that will find recipes that contain exactly the same ingredients:

MATCH (:Cake{name: 'Apple Scones'})-[:CONTAINS]-(a) 
WITH a, size((a)<-[:CONTAINS]-()) as degree
ORDER BY degree ASC
WITH collect(a) as ingredients
WITH tail(ingredients) as list, head(ingredients) as first
MATCH (first)<-[:CONTAINS]-(recipe)
WHERE ALL(i in tail(list) WHERE (i)<-[:CONTAINS]-(recipe))
RETURN recipe

Otherwise you might look for a query that matches all ingredients to all recipes that contain them, and then order by those with the most ingredients in common and take some limited set of results:

MATCH (:Cake{name: 'Apple Scones'})-[:CONTAINS*2]-(recipe)
WITH recipe, count(recipe) as commonIngredients
ORDER BY commonIngredients DESC
LIMIT 5
RETURN recipe