Erlang函数for（）？

Question

From my understanding Erlang doesn't have the capabilities to do a for loop. However in this code snippet it uses the function for() in it. I don't really understand this for() function so any help is apprechiated.

-module(helloworld). 
-export([max/1,start/0]). 

max(N) -> 
   Max = erlang:system_info(process_limit), 
   io:format("Maximum allowed processes:~p~n" ,[Max]), 

   statistics(runtime), 
   statistics(wall_clock), 

   L = for(1, N, fun() -> spawn(fun() -> wait() end) end), 
   {_, Time1} = statistics(runtime),
   {_, Time2} = statistics(wall_clock),
   lists:foreach(fun(Pid) -> Pid ! die end, L),

   U1 = Time1 * 1000 / N, 
   U2 = Time2 * 1000 / N, 
   io:format("Process spawn time=~p (~p) microseconds~n" , [U1, U2]).

wait() ->
   receive 
      die -> void 
   end. 

for(N, N, F) -> [F()]; 
for(I, N, F) -> [F()|for(I+1, N, F)]. 

start()->
   max(1000), 
   max(100000).

Also what's the difference in run time and wall_clock in Erlang? I believe that wallclock is based off computers clock while runtime is based off of some sort of ticks in Erlang? I may be wrong though

Answer 1

I don't really understand this for() function so any help is apprechiated.

Rename the function xyz(). Now, does it make sense?

xyz(N, N, F) -> [F()]; 
xyz(I, N, F) -> [F()|xyz(I+1, N, F)].

The first clause of the xyz() function looks for a 1st and 2nd argument that are identical (N, N...) . If the first two arguments are identical, then xyz() returns a list containing the return value of calling the 3rd argument.

The second clause of the xyz() function will match when the first two arguments are different (I, N, ...) . In that case, the third argument is called and it's return value is the head of a list, with the tail of the list being a recursive call to the xyz() function, where the first argument is incremented.

So, let's try a simple example:

-module(f1).
-compile(export_all).

show() ->
   hello.


xyz(End, End, F) -> [F()]; 
xyz(Start, End, F) -> [F()|xyz(Start+1, End, F)].

test() ->
    xyz(0, 5, fun show/0).

In the shell:

5> c(f1).    
f1.erl:2: Warning: export_all flag enabled - all functions will be exported
{ok,f1}

6> f1:test().
[hello,hello,hello,hello,hello,hello]

And here is another example:

for(End, End) ->
    io:format("~w~n", [End]); 
for(Start, End) -> 
    io:format("~w~n", [Start]),
    for(Start+1, End).


test() ->
    for(0, 5).

In the shell:

12> c(f1).    
f1.erl:2: Warning: export_all flag enabled - all functions will be exported
{ok,f1}

13> f1:test().
0
1
2
3
4
5
ok
14>