Excel VBA错误13“类型不匹配”

Question

I am relatively new to VBA, I've spent the weekend trying to work around the following error. The error 13 is indicated for the line "If uuid(i, 1).value = (Polar Or ID107 Or Nut) Then"

I am currently trying to check cells in a column to see if a specific string is contained in it. If it is then copy the necessary cells in same row. I know the error is due to the string/numerical assignment but I just cant seem to figure out or find a workaround.

My code is below I've also kept previous attempts in (but commented out) to try save some time. I've also tried defining the strings as "Variants" to no avail. no matter what I change ( while still trying to check for string match) this error is fixed on this line.

Any and all help is very greatly appreciated Running Excel 2016, on Win10

Sub rssi_test()

    'Declare/ Define variables
    Dim output As Integer
    Dim i As Integer
    Dim Polar As String 'FF:31:F2:91:28:4A   Polar   H10
    Dim ID107 As String 'D3:AE:CB:BC:E6:C7   ID107   HR
    Dim Nut   As String 'FF:FF:30:00:E8:9D   nut
    Dim holder As String
    Dim point_change As String


    Dim class, uuid, rssi, value1, value2 As Range
    Dim class_results, uuid_results, rssi_results, value1_results, value2_results As Range
    Dim itemCount As Long

    'itemCount = Range("A:A").Rows.Count
    Set class = Range("B:B")
    Set uuid = Range("C:C")
    Set rssi = Range("D:D")
    Set value1 = Range("E:E")
    Set value2 = Range("F:F")

    Polar = "FF:31:F2:91:28:4A"
    ID107 = "D3:AE:CB:BC:E6:C7"
    Nut = "FF:FF:30:00:E8:9D"
    point_change = "moving"
    output = 1

    '''For i = 10000 To itemCount 'Starting value for "i" to full length of sheet
    For i = 1 To 10000

    '''If InStr(uuid.value, Polar, Nut) > 0 Then
    '''l = Application.WorksheetFunction.Match("TEST", Range("A1:A100"), 0)
    '''Worksheet.Find(uuid(i, 1)) = (Polar Or ID107 Or Nut)

    '''holder = uuid(i,1)
    '''If holder = (Polar Or ID107 Or Nut) Then


    If uuid(i, 1).value = (Polar Or ID107 Or Nut) Then

        'UUID Matches
        If value1(i, 1) < -1 Then
            Results output
            output = output + 1
        End If

    ElseIf uuid(i, 1) = point_change Then
        'Point change indicator
        Results output
        output = output + 1

    End If
    Next i
    '''i = i + 1

End Sub

Sub Results(x)
    Set class = Range("B:B")
    Set uuid = Range("C:C")
    Set rssi = Range("D:D")
    Set value1 = Range("E:E")
    Set value2 = Range("F:F")

    Set class_results = Range("L:L")
    Set uuid_results = Range("M:M")
    Set rssi_results = Range("N:N")
    Set value1_results = Range("O:O")
    Set value2_results = Range("P:P")

        class_results(x, 1) = class(x, 1)
        uuid_results(x, 1) = uuid(x, 1)
        rssi_results(x, 1) = rssi(x, 1)
        value1_results(i, 1) = value1(i, 1)
        value2_results(i, 1) = value2(i, 1)
End Sub

Answer 1

This should be written:

 If uuid(i, 1).value = Polar Or uuid(i, 1).value = ID107 OR uuid(i, 1).value =Nut Then

OR and And are used between Booleans ( TRUE or FALSE ), not between Strings. So you end up resolving to something like:

If True OR False or False Then

Which will resolve to True and pass the IF .

Answer 2

you could use Select Case syntax:

For i = 1 To 10000
    Select Case uuid(i, 1).Value
        Case Polar, ID107, Nut
            'UUID Matches
            If value1(i, 1) < -1 Then
                Results output
                output = output + 1
            End If

        Case point_change
            'Point change indicator
            Results output
            output = output + 1
    End Select
Next