如何从列中提取字符串是否为电子邮件格式？

Question

I wanted to extract different emails included in a specific column. The column may have other type of strings which may not be emails which I want to exclude and I just want emails.

Table 1 
ID         Value 
1          Sent Email successfully to John.Muller@gmail.com, Jim.James@gmail.com, Bob.King@hotmail.com and it will be sent tomorrow
2          Email not successful to adam.sandy@yahoo.com, Trisha.stratus@gmail.com, lindy.123@gmail.com  and it will not be sent today

If we see this format, I have 3 different emails on each ID, and I wanted to know if there is any way which I could get the data in this format.

  Expected output 
ID         Value 
1          John.Muller@gmail.com, Jim.James@gmail.com, Bob.King@hotmail.com  
2          adam.sandy@yahoo.com, Trisha.stratus@gmail.com, lindy.123@gmail.com   

If this type of output is also possible, it would be great.

  Another Possible Output (this would be awesome if possible) 
ID         Value 
1          John.Muller@gmail.com 
1          Jim.James@gmail.com 
1          Bob.King@hotmail.com  
2          adam.sandy@yahoo.com 
2          Trisha.stratus@gmail.com 
2          lindy.123@gmail.com   

Answer 1

Here is an inline approach

Example

Select A.ID
      ,Value = B.RetVal
 From  YourTable A
 Cross Apply (
                Select RetSeq = Row_Number() over (Order By (Select null))
                      ,RetVal = v.value('(./text())[1]', 'varchar(150)')
                 From  (values (convert(xml,'<x>' + replace(replace(Value,' ',','),',','</x><x>')+'</x>'))) x(n)
                 Cross Apply n.nodes('x') node(v)
              ) B
 Where RetVal like '%@%.___'

Returns

ID  Value
1   John.Muller@gmail.com
1   Jim.James@gmail.com
1   Bob.King@hotmail.com
2   adam.sandy@yahoo.com
2   Trisha.stratus@gmail.com
2   lindy.123@gmail.com

Edit To return as one line

Select A.ID
      ,B.Value 
 From  YourTable A
 Cross Apply (
                Select Value = Stuff((Select ', ' +RetVal 
                  From (
                        Select RetSeq = Row_Number() over (Order By (Select null))
                              ,RetVal = v.value('(./text())[1]', 'varchar(150)')
                         From  (values (convert(xml,'<x>' + replace(replace(Value,' ',','),',','</x><x>')+'</x>'))) x(n)
                         Cross Apply n.nodes('x') node(v)
                       ) B1
                  Where RetVal like '%@%.___'
                  Order by RetSeq
                  For XML Path ('')),1,2,'') 
              ) B

Returns

ID  Value
1   John.Muller@gmail.com, Jim.James@gmail.com, Bob.King@hotmail.com
2   adam.sandy@yahoo.com, Trisha.stratus@gmail.com, lindy.123@gmail.com

Answer 2

Try this Function

alter FUNCTION [dbo].[FnSplit2]
(
@List nvarchar(max),
@SplitOn1 nvarchar(5),
@SplitOn2 nvarchar(5)

)  
--Akram Mustafa
RETURNS @RtnValue table 
(

Id int identity(1,1),
Value nvarchar(1000)
) 
AS  
BEGIN
declare @SplitOn varchar(5)
While (Charindex(@SplitOn1,@List)>0  or Charindex(@SplitOn2,@List)>0 )
Begin 
if Charindex(@SplitOn1,@List)<Charindex(@SplitOn2,@List) and Charindex(@SplitOn1,@List)> 0
begin
    set @SplitOn = @SplitOn1
end
else
begin
    set @SplitOn = @SplitOn2
end
Insert Into @RtnValue (value)
Select
Value = ltrim(rtrim(Substring(@List,1,Charindex(@SplitOn,@List)-1))) 
Set @List = Substring(@List,Charindex(@SplitOn,@List)+DATALENGTH(@SplitOn),DATALENGTH(@List))
End 

Insert Into @RtnValue (Value)
Select Value = ltrim(rtrim(@List))
Return
END

it will split for either comma or white space

declare @MyTable as table (id int, value varchar(1000))
insert into @MyTable(id, value)
values(1, 'Sent Email successfully to John.Muller@gmail.com, Jim.James@gmail.com, Bob.King@hotmail.com and it will be sent tomorrow')

insert into @MyTable(id, value)
values(2, 'Email not successful to adam.sandy@yahoo.com, Trisha.stratus@gmail.com, lindy.123@gmail.com  and it will not be sent today')

declare @str varchar(max)

 SELECT @str = LEFT(Value, LEN(Value) - 1)
FROM (
    SELECT Value + ', '
    FROM @MyTable
    FOR XML PATH ('')
  ) c (Value)

 select value from dbo.fnSplit2(@str,',',' ')
 where value like '%@%'

end result will be

value
John.Muller@gmail.com
Jim.James@gmail.com
Bob.King@hotmail.com
adam.sandy@yahoo.com
Trisha.stratus@gmail.com
lindy.123@gmail.com