将微型锌模型分解为用户定义的函数

Question

For my larger minizinc model, I need a function which basically answers: "is there a subset of this array in which the sum of it is within $tolerance of $target" (and returns a boolean).

By itself this is pretty easy to write in minizinc. eg

int: tolerance = 3;
int: target = 200;
int: amountsCount = 7;
array[1..amountsCount] of int: amounts = [23, 345, 230, 100, 25, 28, 25];


array[1..amountsCount] of var bool: includeAmount;

var int: subsetAmount = sum([(if includeAmount[i] then amounts[i] else  0 endif) | i in 1..amountsCount]);


var bool: solvable = abs(subsetAmount - target) < tolerance;
solve maximize bool2int(solvable);

output ["solvable=", show(solvable), " included: ", show(includeAmount), " subset amount:", show(subsetAmount)];

But how could I make this a user-defined function (that returns a boolean "solvable") so I can use it from my real model?

Answer 1

You can introduce a user-defined predicate that returns the value of solvable in your model:

predicate has_subset_within_tolerance(array[1..amountsCount] of int: amounts_array) =
    let {
         var int: subsetAmount = sum([(if includeAmount[i] then amounts[i] else  0 endif) | i in 1..amountsCount]);
    } in 
         abs(subsetAmount - target) < tolerance
    ;

Predicates are like functions, just that they return Boolean values. In the predicate I introduce the local variable subsetAmount and constrain it the same way you did in your initial model. Then I post the expression that needs to hold for the predicate to return true: abs(subsetAmount - target) < tolerance .

You can then use this predicate in your model, for instance in the solve statement, in the following way:

int: tolerance = 3;
int: target = 200;
int: amountsCount = 7;
array[1..amountsCount] of int: amounts = [23, 345, 230, 100, 25, 28, 25];

array[1..amountsCount] of var bool: includeAmount;

solve maximize bool2int(has_subset_within_tolerance(amounts));

% don't forget to insert the predicate here as well

EDIT :

You can also add your variable includeAmount as a parameter to the prediate:

predicate has_subset_within_tolerance(array[1..amountsCount] of int: amounts_array,
                                      array[1..amountsCount] of var bool: includeAmount)=
 let {
     var int: subsetAmount = sum([(if includeAmount[i] then amounts_array[i] else  0 endif) | i in 1..amountsCount]);
  } in 
     abs(subsetAmount - target) < tolerance
 ; 

then you can call your predicate with different variables, such as includeAmount1 and includeAmount2 :

int: tolerance = 3;
int: target = 200;
int: amountsCount = 7;
array[1..amountsCount] of int: amounts1 = [23, 345, 230, 100, 25, 28, 25];
array[1..amountsCount] of int: amounts2 = [20, 35, 10, 400, 65, 19, 69];

array[1..amountsCount] of var bool: includeAmount1;
array[1..amountsCount] of var bool: includeAmount2;

solve maximize 
   bool2int(has_subset_within_tolerance(amounts1, includeAmount1))
 + bool2int(has_subset_within_tolerance(amounts2, includeAmount2));

You can also add target and tolerance as parameters to the predicate, in case they also depend on the different includeAmount variables.