如何处理需要额外类型约束的类型类实例

Question

I found myself in a situation where a typeclass instance I want to define requires additional type constraints. Specifically I want to define Show for a type Trie a :

data Trie a = Node {
    label :: a,
    edges :: DM.Map a (Trie a),
    isFinal :: Bool
}

while the instance for Show is:

import qualified Data.Tree as DT

instance (Show a, Eq a, Eq (Trie a)) => Show (Trie a) where
    show trie@(Node label edges _) = DT.drawTree (mapTree show $ toDataTree trie)

I required Eq a and Eq (Trie a) here, as I use toDataTree which converts a Trie a to a DT.Tree a and entails these type constraints:

import qualified Data.Map as DM

toDataTree :: (Eq a, Eq (Trie a)) => Trie a -> DT.Tree a
toDataTree (Node label edges isFinal)
    | edges == DM.empty = DT.Node label (map toDataTree (DM.elems edges))
    | otherwise = DT.Node label []

mapTree :: (a -> b) -> DT.Tree a -> DT.Tree b
mapTree f (DT.Node rootLabel subForest) = DT.Node (f rootLabel) $ map (mapTree f) subForest

Now while this does compile, when I actually want to call print on a Trie a (where a = Char in this case) I get

• No instance for (Eq (Trie Char)) arising from a use of ‘print’
• In a stmt of an interactive GHCi command: print it

This must be because I needed to add these additional type constraints to the instance of Show . So my approach is probably wrong.

What is the correct solution for additional type constraints being required for a type class instance definition?

Answer 1

I assume there's a bug in your program in the toDataTree guard and you meant:

| edges /= DM.empty = ...

However, you don't need Eq instances to check that a map is empty. If you use DM.null instead, you can drop the Eq constraints from toDataTree and from the Show instance:

toDataTree :: Trie a -> DT.Tree a
toDataTree (Node label edges isFinal)
    | not (DM.null edges) = DT.Node label 
                             (map toDataTree (DM.elems edges))
    | otherwise = DT.Node label []

In fact, if the map is empty, then mapping over its elements will produce an empty list anyway, so you can further simplify this to:

toDataTree :: Trie a -> DT.Tree a
toDataTree (Node label edges isFinal)
  = DT.Node label (map toDataTree (DM.elems edges))

Anyway, that should solve your immediate problem.

Setting all that aside, the reason for the error is that you haven't provided any Eq instance for any Trie . You could add a deriving (Eq) clause to the definition for Trie :

data Trie a = Node {
    label :: a,
    edges :: DM.Map a (Trie a),
    isFinal :: Bool
} deriving (Eq)

This might give you a scary warning about fragile inner bindings, but you can drop the Eq (Trie a) constraints (because they will be implied by the Eq a constraint) from both the Show instance and toDataTree to make the warning go away.

Still, as mentioned, you don't really want to do this, because using DM.null and bypassing the Eq instances entirely is better practice.