Removeduplicates 无法用于大小取决于数据范围的数组

Question

There are 2 set of codes below, the upper one (as comments) doesn't work, while the one below works. My goal is to remove duplicates from a range that I do not know its number of columns beforehand. The one above should also create an array similar to Array(1,2,3,4,5). Any idea why the one at the bottom works while the one on top doesn't? Thanks in advance! (Pasted the wrong code block earlier.)

The error I got is Run Time error 5: Invalid procedure call or argument.

Sub RemoveDup(datarange As Range)

    Dim ColArray() As Variant
    Dim i As Integer

'    ReDim ColArray(1 To datarange.Columns.Count())
'
'    For i = 1 To datarange.Columns.Count()
'        ColArray(i) = i
'    Next i

    ColArray = Array(1, 2, 3, 4, 5)

    datarange.RemoveDuplicates Columns:=(ColArray), _
        Header:=xlNo

End Sub

Answer 1

You need to start building the array from 0... as follows:

Dim datarange As Range
Dim ColArray() As Variant
Dim i As Integer

Set datarange = Range("A1:E6")
ReDim ColArray(0 To datarange.Columns.Count() - 1)

For i = 0 To datarange.Columns.Count() - 1
    ColArray(i) = i + 1
Next i

datarange.RemoveDuplicates Columns:=(ColArray), Header:=xlNo

Note: I've just input the range as Range("A1:A6") but you can specify whatever you want.

Answer 2

That's my version as a parametrized sub and use of With

Sub RemoveDup(datarange As Range)
' removes duplicate taking all columns into account
Dim i As Long
Dim varItems() As Variant
    With datarange
        ReDim varItems(0 To .Columns.Count - 1)
        For i = 1 To .Columns.Count
            varItems(i - 1) = i
        Next i
        .RemoveDuplicates Columns:=(varItems), Header:=xlNo
    End With
End Sub