MySQL计数出现到新列

Question

is posible to make a query to count ocurrences in one colum and show the number of ocurrences in different columns?

Example:

+--------+
| Status |
+--------+
| 2      |
+--------+
| 1      |
+--------+
| 2      |
+--------+
| 3      |
+--------+
| 3      |
+--------+
| 2      |
+--------+

wanted result

+---------+---------+---------+
| status1 | status2 | status3 |
+---------+---------+---------+
| 1       | 3       | 2       |
+---------+---------+---------+

I am limited using VFP ODBC driver

Answer 1

You should really handle display related things in your application code. However, you can use Conditional Aggregation with Group By :

SELECT 
  COUNT(CASE status WHEN 1 THEN status END) AS status1, 
  COUNT(CASE status WHEN 2 THEN status END) AS status2, 
  COUNT(CASE status WHEN 3 THEN status END) AS status3
FROM your_table_name 

DB Fiddle DEMO

Answer 2

You have tagged the question with VFP, mysql and ODBC so I would assume the question is about doing this in VFP with mySQL backend (since VFP doesn't have an ODBC driver since V6.x). And I would also think that your status values might be more than 3, out of order with gaps maybe but less than 256 in total (otherwise if they were constant 1,2,3 you could simply do a count(case when ... then ... end) as status1 ... like query).

Then you can get the results from mySQL with a simple query like:

SQLExec(m.lnYourhandle, 'select status, count(*) as counts'+;
   ' from myTable group by status','crsCounts')

Then cross tab it with a simple code. The whole code would look like:

Local lnHandle, ix

lnHandle=Sqlstringconnect('Driver={MySQL ODBC 3.51 Driver};Server=localhost;Database=myDataBase;'+;
    'User=myUsername;Password=myPassword;Option=3;')
SQLExec(m.lnHandle,'select status, Count(*) as counts'+;
    ' from myTable'+;
    ' group by status'+;
    ' order by status','crsCounts')
SQLDisconnect(0)


Local Array laCounts[1], laStruct[Reccount('crsCounts'),4]
* Get ProductId by transforming it to style
* 'StatusXXX' as field name, i as fieldtype, 4, 0 as field length
Select 'Status'+Padl(Status,3,'0'), 'I', 4, 0 ;
    from crsCounts ;
    into Array laStruct

* Get the counts into an array - already ordered by status
Select counts From crsCounts Into Array laCounts
* transpose the array from being [rows,1] to [1,cols]
Dimension laCounts[1, Alen(laCounts,1)]

* create the result cursor using laStructs array and insert data
Create Cursor crsXTabbed From Array laStruct
Insert Into crsXTabbed From Array laCounts
Browse