Perl 正则表达式查找并返回每个可能的匹配项

Question

Im trying to create a while loop that will find every possible sub-string within a string. But so far all I can match is the largest instance or the shortest. So for example I have the string

EDIT CHANGE STRING FOR DEMO PURPOSES

"A.....B.....B......B......B......B"

And I want to find every possible sequence of "A.......B"

This code will give me the shortest possible return and exit the while loop

while($string =~ m/(A(.*?)B)/gi) {
    print "found\n";
    my $substr = $1;
    print $substr."\n";
}

And this will give me the longest and exit the while loop.

$string =~ m/(A(.*)B)/gi

But I want it to loop through the string returning every possible match. Does anyone know if Perl allows for this?

EDIT ADDED DESIRED OUTPUT BELOW

found
A.....B
found
A.....B.....B
found
A.....B.....B......B
found
A.....B.....B......B......B
found
A.....B.....B......B......B......B

Answer 1

There are various ways to parse the string so to scoop up what you want.

For example, use regex to step through all A...A substrings and process each capture

use warnings;
use strict;
use feature 'say';

my $s = "A.....B.....B......B......B......B";

while ($s =~ m/(A.*)(?=A|$)/gi) {
    my @seqs = split /(B)/, $1; 
    for my $i (0..$#seqs) {
        say @seqs[0..$i] if $i % 2 != 0;
    }   
}

The (?=A|$) is a lookahead, so .* matches everything up to an A (or the end of string) but that A is not consumed and so is there for the next match. The split uses () in the separator pattern so that the separator, too, is returned (so we have all those B's). It only prints for an even number of elements, so only substrings ending with the separator ( B here).

The above prints

A.....B
A.....B.....B
A.....B.....B......B
A.....B.....B......B......B
A.....B.....B......B......B......B

There may be bioinformatics modules that do this but I am not familiar with them.