免费使用RPGLE中的数组访问外部（DSPF）字段

Question

In the old RPG III and the non-free RPGLE/RPG IV you could "rename" fields you get from either a record of a PF/LF or a record from a DSPF .

This lead to possibilities like grouping several lines of input (additional order text) into a array. So I didn't have to MOVEL or EVAL ottxt1 to the external described field x1txt1 , ottxt2 to x1txt2 and so on.

I'd only had to rename the LF record and the DSPF record fields to the array-fields, read the record and shift them from the one array to the other and display my DSPF record

 H DECEDIT('0,') DATEDIT(*DMY.) dftactgrp(*no)

 Fsls001    cf   e             workstn
 Fordtxtl0  if   e           k disk

 D ot              s             20a   dim(6)
 D x1              s             20a   dim(6)

 Iordtxtr
 I              ottxt1                      ot(1)
 I              ottxt2                      ot(2)
 I              ottxt3                      ot(3)
 I              ottxt4                      ot(4)
 I              ottxt5                      ot(5)
 I              ottxt6                      ot(6)
 Isls00101
 I              x1txt1                      x1(1)
 I              x1txt2                      x1(2)
 I              x1txt3                      x1(3)
 I              x1txt4                      x1(4)
 I              x1txt5                      x1(5)
 I              x1txt6                      x1(6)

 C     k$or00        klist
 C                   kfld                    otonbr
 C                   kfld                    otopos

 C                   eval      otonbr = 2
 C                   eval      otopos = 2
 C     k$or00        chain     ordtxtr
 C                   if        %found(ordtxtl0)
 C                   eval      x1 = ot
 C                   endif
 C
 C                   exfmt     sls00101
 C
 C                   move      *on           *inlr 

But is this also possible in *FREE RPGLE ? And if so, how?

Answer 1

You can define data structures containing the fields from the files, and overlay them with an array.

Replace your I specs and array definitions with these data structures. You don't have to specify anything besides the field names for the fields from the externally-described file.

dcl-ds otDs;
   ottxt1;
   ottxt2;
   ottxt3;
   ottxt4;
   ottxt5;
   ottxt6;
   ot like(ottxt1) dim(6) pos(1);
end-ds;

dcl-ds x1Ds;
   x1txt1;
   x1txt2;
   x1txt3;
   x1txt4;
   x1txt5;
   x1txt6;
   x1 like(x1txt1) dim(6) pos(1);
end-ds;