在find（）内部使用OR子句

Question

I need to fetch a single row from database table using DBIx::Class when one of the two descriptor columns is like a provided data.

My SQL select looks like this:

select id from products where (code = 'VALUE' or description like '%VALUE%')

The table has unique constraint what ensures me that only one row exists for the VALUE.

How can I formulate this SQL using DBIx::Class?

The following code returns me the value 1 but not the correct data:

my $param = 'VALUE';
my $res = $c->stash->{products_rs}->search(
    -or => [
        { code => { '=', $param } },{ description => { 'like', '%'.$param.'%' } }
    ],
);

I should use the find method to return a single row but then I can not use the -or clause.

Any suggestion?

---

Hi, I am back. I decided to create myself the classes. First the schema class:

package prod::Schema;
use utf8;
use Moose;
use MooseX::MarkAsMethods autoclean => 1;
extends 'DBIx::Class::Schema';
__PACKAGE__->load_namespaces(
    default_resultset_class => 'ResultSet',
);
__PACKAGE__->meta->make_immutable(inline_constructor => 0);
1;

I am using a base Result class for my table:

package prod::Schema::Result;
use strict;
use warnings;
use base qw( DBIx::Class::Core );
__PACKAGE__->load_components(
    "InflateColumn::DateTime", 
    "TimeStamp", 
    "EncodedColumn"
);
1;

Each table then uses a ResultSet base class:

package prod::Schema::ResultSet;
use strict;
use warnings;
use base qw( DBIx::Class::ResultSet );
__PACKAGE__->load_components('Helper::ResultSet::OneRow');
1;

and the Product class itself:

package prod::Schema::Result::Products;
use strict;
use warnings;
use utf8;
use Moose;
use MooseX::NonMoose;
use MooseX::MarkAsMethods autoclean => 1;
extends 'prod::Schema::Result';
__PACKAGE__->table("prod.products");
__PACKAGE__->add_columns("id",  {
    data_type => "uuid",
    default_value => \"uuid_generate_v4()",
    is_nullable => 0,
    size => 16,
}, "code", {
    data_type => "varchar", is_nullable => 0, size => 2
}, "name", {
    data_type => "varchar", is_nullable => 0, size => 128 },
);
__PACKAGE__->set_primary_key("id");
__PACKAGE__->add_unique_constraint("uk_products_code", ["code"]);
__PACKAGE__->meta->make_immutable;
1;

The application uses this model class:

package prod::Model::DB_T;
use strict;
use base 'Catalyst::Model::DBIC::Schema';
__PACKAGE__->config(
    schema_class => 'prod::Schema',
    connect_info => {
        dsn => 'dbi:Pg:dbname=p12;host=localhost',
        user => 'username',
        password => 'password',
        AutoCommit => q{1},
    }
);
1;

The Root is this:

package prod::Controller::Root;
use Moose;
use namespace::autoclean;
use Data::Dumper;
BEGIN { extends 'Catalyst::Controller' }
__PACKAGE__->config(namespace => '');
sub index :Path :Args(0) {
    my ($self, $c) = @_;
    my $Products = $c->model('DB_T::Products');
    my $product = $Products->search(
        -or => [
        { code => { '=', 'x' } },{ name => { 'like', '%'.'X'.'%' } }
        ],
    )->one_row;
    my $str = ''.$product->name;
    $c->response->body('product: '.$str);
}
sub default :Path {
    my ($self, $c) = @_;
    $c->response->body('Page not found');
    $c->response->status(404);
}
sub end : ActionClass('RenderView') {}
__PACKAGE__->meta->make_immutable;
1;

Now, I am using this one_row from that helper class, I do get the wanted result but the SQL statement remains open till I shutdown the application.

@Alexander Hartmaier you said that I should avoid this. But how? What is wrong with this code?

Answer 1

Either by using the one_row method from the highly recommended DBIx::Class::Helper distribution or by copying its code.

first shouldn't be used because it keeps the database statement handle open.