VBA数据反应式显示Yahoo Finance的财务编号

Question

I googled data-reactid and it seems it won't work with VBA in most cases.

But I still think there maybe a possibility to get an answer. I want to get numbers in " Total Cash Flow From Operating Activities "

https://finance.yahoo.com/quote/BABA/cash-flow?p=BABA

Sub YFinance()

    Dim XMLReq As New MSXML2.XMLHTTP60
    Dim HTMLDoc As New MSHTML.HTMLDocument
    Dim i As Integer
    Dim strUrl As String



    XMLReq.Open "GET", "https://finance.yahoo.com/quote/BABA/cash-flow?p=BABA", False
    XMLReq.send

    If XMLReq.Status <> 200 Then
        MsgBox "Error!"
        Exit Sub
    End If

    HTMLDoc.body.innerHTML = XMLReq.responseText

    Set XMLReq = Nothing

    MsgBox HTMLDoc.getElementsById("Bdbw(0px)! H(36px)")(0).innerText






End Sub

Answer 1

getElementById returns a single node so you wouldn't index into it as you are doing. There is no method getElementsById so that should fail with an error.

You could use the class and escape the special characters and index into returned collection

MsgBox HTMLDoc.querySelectorAll(".Bdbw\(0px\)\!")(1).innerText

Or pass the compound class to getElementsByClassName :

MsgBox HTMLDoc.getElementsByClassName("Bdbw(0px)! H(36px)")(1).innerText

The attribute (not id) data-reactid can vary between page and output (as it does in this case - the id is 113 for the row in the output. In this instance it may be safer to use table and row indices

MsgBox HTMLDoc.getElementsByTagName("table")(2).getElementsByTagName("tr")(9).innerText

If you want column by column for that row:

Dim td As Object, tds As Object
Set tds = HTMLDoc.getElementsByTagName("table")(2).getElementsByTagName("tr")(9).getElementsByTagName("td")
For Each td In tds
    Debug.Print td.innerText
Next

Or

Dim td As Object, tds As Object
Set tds = HTMLDoc.getElementsByClassName("Bdbw(0px)! H(36px)")(1).getElementsByTagName("td")
For Each td In tds
    Debug.Print td.innerText
Next

As I said, the data-reactid can flex but if you want to know how to apply an attribute selector for this, see:

MsgBox HTMLDoc.querySelector("tr[data-reactid='113']").innerText

Answer 2

You can try the following to play safe. Once the for loop gets the required node, it will fetch you the desired content and exit the loop.

Sub FetchFinanceInfo()
    Dim XMLReq As New XMLHTTP60, HTMLDoc As New HTMLDocument
    Dim post As Object, I&

    XMLReq.Open "GET", "https://finance.yahoo.com/quote/BABA/cash-flow?p=BABA", False
    XMLReq.send
    HTMLDoc.body.innerHTML = XMLReq.responseText

    For Each post In HTMLDoc.getElementsByTagName("span")
        If InStr(post.innerText, "From Operating Activities") > 0 Then
            With post.ParentNode.ParentNode.getElementsByTagName("td")
                For I = 1 To .Length - 1
                    Debug.Print .Item(I).innerText
                Next I
            End With
            Exit For
        End If
    Next post
End Sub