ActiveSheet.ShowAllData在2台计算机上返回不同的结果

Question

I have some macro that filters all the data (250 rows) by one column, then deletes the data that is hidden after filtering.

Next step is unfiltering whole sheet using ActiveSheet.ShowAllData.

What's strange, on my machine after unfiltering my used range seems to be 200 rows (50 rows has been deleted).

However on another machine, with the same Excel version (Office365), after unfiltering and deleting 50 rows the visible range is 1,048,576 rows (what pretty much messes up further autofills etc.)

The code is as follows:

Dim lastRow As Long
Dim iCntr As Long

Range("A:AI" & Lines).AutoFilter Field:=32, Criteria1:= _
    "2611"
lastRow = Cells(Rows.Count, 1).End(xlUp).Row
For iCntr = lastRow To 1 Step -1
    If Rows(iCntr).Hidden = True Then Rows(iCntr).EntireRow.Delete
Next

ActiveSheet.ShowAllData

Answer 1

I recommend to collect all the rows that need to be deleted in a variable RowsToDelete and then show all data before you delete all the rows at once. Not sure if this finally fixes your issue but at least this is a lot faster than deleting each row after another.

Option Explicit

Public Sub DeleteAllHiddenRows()
    Dim ws As Worksheet
    Set ws = ActiveSheet

    Dim LastRow As Long
    LastRow = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row

    ws.Range("A:AI").AutoFilter Field:=32, Criteria1:="2611"

    Dim RowsToDelete As Range

    Dim iRow As Long
    For iRow = 1 To LastRow
        If ws.Rows(iRow).Hidden Then
            If RowsToDelete Is Nothing Then
                Set RowsToDelete = ws.Rows(iRow)
            Else
                Set RowsToDelete = Union(RowsToDelete, ws.Rows(iRow))
            End If
        End If
    Next iRow

    ws.ShowAllData
    RowsToDelete.EntireRow.Delete
End Sub

Answer 2

Sub clear_filter()
Dim sh As Worksheet



sh=activeworksheet
If sh.AutoFilterMode Then

 On Error GoTo 1
  sh.ShowAllData
    sh.AutoFilterMode = False
End If

1

MsgBox "Data filters cleared", vbInformation


    End Sub